نصيحة: اللغات الأخرى مترجمة من قبل Google. يمكنك زيارة English نسخة من هذا الرابط.
تسجيل الدخول
x
or
x
x
التسجيل
x

or

تفوق SUMPRODUCT وظيفة

في Excel ، يمكن استخدام دالة SUMPRODUCT لمضاعفة عمودين أو أكثر أو صفائف معًا ، ثم الحصول على مجموع المنتجات. في الواقع ، يعد SUMPRODUCT وظيفة مفيدة يمكن أن تساعد في حساب قيم الخلايا أو جمعها بمعايير متعددة مثل الدالة COUNTIFS أو SUMIFS. ستقدم هذه المقالة بناء جملة الدالة وبعض الأمثلة لهذه الدالة SUMPRODUCT.


بناء الجملة:

بناء جملة الدالة SUMPRODUCT في Excel هو:

=SUMPRODUCT (array1, [array2], ...)

الحجج:

  • array1: مطلوب. الصفيف الأول أو نطاق الخلايا الذي تريد ضربه ثم إضافته.
  • array2: اختياري. الصفيف الثاني أو نطاق الخلايا الذي تريد ضربه ثم إضافته.

الملاحظات:

  • 1. إذا كانت هناك قيم غير رقمية في النطاق الخاص بك ، فإن SUMPRODUCT يعاملها كأصفار.
  • 2. إذا كان للصفيفات أو النطاقات عدد مختلف من الصفوف والأعمدة ، فستُرجع الدالة SUMPRODUCT # VALUE! خطأ.
  • 3. إذا كانت هناك اختبارات منطقية في المصفوفات ، فستقوم بإنشاء قيم TRUE و FALSE. في معظم الحالات ، تحتاج إلى تحويلها إلى 1 و 0 باستخدام عامل التشغيل الأحادي المزدوج (-).
  • 4. يمكن أن تتعامل دالة SUMPRODUCT مع وسيطات 255 في Excel 2007 والإصدارات الأحدث ، وسيطات 30 فقط في إصدارات Excel السابقة.
  • 5. لا يدعم SUMPRODUCT أحرف البدل.

عودة:

إرجاع نتيجة الصفائف مضاعفة ولخص.


أمثلة:

مثال 1: الاستخدام الأساسي لوظيفة SUMPRODUCT

الاستخدام الأساسي لـ SUMPRODUCT هو ضرب عمودين ثم إضافتهما ، على سبيل المثال ، لديك بيانات لقطة الشاشة التالية ، والآن تريد مضاعفة الطلب وسعر الوحدة ، ثم جمع كل نتائج الضرب معًا للحصول على السعر الكلي.

للتعامل مع هذه المهمة ، يرجى تطبيق الصيغة أدناه:

=SUMPRODUCT(B2:B7,C2:C7)

تفسير: هذه الصيغة SUMPRODUCT(B2:B7,C2:C7) = B2*C2+B3*C3+B4*C4+B5*C5+B6*C6+B7*C7.

ثم ، اضغط أدخل المفتاح ، يتم ضرب الخلايا الموجودة في العمود B بخلاياها المقابلة في نفس الصف من العمود C ، وتتم إضافة النتائج. انظر قطة:


مثال 2: مجموع الخلايا مع معايير متعددة مع دالة SUMPRODUCT

باستثناء دالة SUMIFS لتجميع قيم الخلايا بناءً على شروط متعددة ، فإن وظيفة SUMPRODUCT يمكنها أيضًا حل هذه المهمة بسرعة وسهولة.


الحالة 1: قيم خلية المجموع إذا كانت تحتوي على نص معين في عمود آخر

لنفترض أن لديك جدول بيانات كما هو موضح أدناه ، والآن ، تريد حساب السعر الإجمالي للمنتج وهو KTE والاسم هو David ، كيف يمكنك القيام به باستخدام صيغة SUMPRODUCT في Excel؟

1. الرجاء إدخال أو نسخ أي من الصيغ أدناه في خلية فارغة:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12="David"), D2:D12)
=SUMPRODUCT((A2:A12="KTE")*(B2:B12="David")*D2:D12)
  • نصائح: في الصيغة أعلاه:
  • A2: A12 = "KTE": هو المعيار الأول_المعايير التي تريد جمعها بناءً على.
  • B2: B12 = "ديفيد": هو المعيار الثاني _ المعايير والمعايير التي تريد جمعها بناءً على.
  • D2: D12: هو نطاق المبلغ الذي تريد جمع قيم الخلية.

2. ثم اضغط أدخل المفتاح للحصول على النتيجة حسب حاجتك:


Case2: مجموع الخلايا مع معايير متعددة مع منطق OR

لتجميع الخلايا بناءً على معايير متعددة مع منطق OR ، يجب عليك استخدام رمز الجمع (+) لربط الشروط المتعددة معًا داخل دالة SUMPRODUCT.

على سبيل المثال ، أريد أن ألخص السعر الإجمالي للمنتج KTE و KTO في العمود A كما هو موضح أدناه:

الرجاء تطبيق الصيغة التالية في خلية فارغة:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"), C2:C12)

ثم ، اضغط أدخل المفتاح ، تم حساب السعر الإجمالي للمنتج KTE و KTO ، انظر لقطة الشاشة:


Case3: مجموع الخلايا مع معايير متعددة مع منطق OR و

في بعض الحالات ، قد تحتاج إلى جمع الخلايا باستخدام منطق OR و AND في نفس الوقت. وظيفة SUMPRODUCE يمكن أن تحل هذه المهمة بسهولة.

النجمة (*) يستخدم عامل التشغيل AND.

علامة زائد (+) يستخدم كمشغل OR.

دعنا نرى مثالًا ، لتلخيص السعر الإجمالي للمنتج الذي هو KTE و KTO عندما يكون حجم البيع أكبر من 200.

يجب عليك نسخ أو إدخال الصيغة أدناه:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO"))*C2:C12)

ثم اضغط أدخل المفتاح للحصول على النتيجة حسب حاجتك:


مثال 3: عد الخلايا ذات معايير متعددة مع دالة SUMPRODUCT

بشكل عام ، يمكن أن تساعدنا دالة SUMPRODUCT هذه أيضًا في حساب الخلايا التي تحتوي على معايير متعددة في Excel. مثل قيم المجموع ، تحتاج فقط إلى إزالة وسيطة sum_range من الصيغة.


Case1: عد الخلايا مع معايير متعددة مع منطق AND

هنا ، أريد أن أحسب الخلايا التي يكون المنتج KTE والبيع أكبر من 200. لذلك ، يرجى استخدام أي من الصيغ أدناه:

=SUMPRODUCT(--(A2:A12="KTE"), --(B2:B12>200))
=SUMPRODUCT((A2:A12="KTE")*(B2:B12>200))
  • نصائح: في الصيغة أعلاه:
  • A2: A12 = "KTE": هو المعيار الأول_المقاييس والمعايير التي تريد حسابها بناءً على.
  • B2: B12> 200: هو المعيار الثاني _ المعايير والمعايير التي تريد حسابها بناءً على.

ثم ، اضغط أدخل المفتاح للحصول على عدد النتيجة:


Case2: عد الخلايا مع معايير متعددة مع المنطق OR

لحساب عدد المنتجات KTE و KTO في العمود A ، يرجى تطبيق هذه الصيغة:

=SUMPRODUCT((A2:A12="KTE")+(A2:A12="KTO"))

ثم ، اضغط أدخل مفتاح للحصول على رقم المنتج KTE و KTO. انظر قطة:


Case3: عد الخلايا مع معايير متعددة مع OR و AND المنطق

لحساب عدد المنتجات KTE و KTO التي تزيد مبيعاتها عن 200 ، يجب عليك تطبيق الصيغة التالية:

=SUMPRODUCT((B2:B12>200)*((A2:A12="KTE")+(A2:A12="KTO")))

ثم اضغط أدخل المفتاح للحصول على عدد النتائج التي تحتاجها:


مثال 4: احسب المتوسط ​​المرجح باستخدام دالة SUMPRODUCT

عادة ، يمكننا حساب متوسط ​​نطاق الخلايا بسرعة وسهولة. ولكن ، إذا كنت تريد حساب متوسط ​​قائمة القيم بمستويات مختلفة من الأهمية ، فهذا يعني حساب المتوسط ​​المرجح. لا توجد وظيفة مباشرة للحصول عليها في Excel. ولكن ، يمكن أن تساعدك الدالة SUMPRODUCT في التعامل معها.

على سبيل المثال ، لدي جدول لإحصائيات الدرجات للطالب ، تأخذ كل مهمة أوزانًا مختلفة كما هو موضح أدناه.

لحساب المتوسط ​​المرجح ، يرجى استخدام الصيغة التالية:

=SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6)

تفسير: هذه الصيغة: SUMPRODUCT(B2:B6, C2:C6) / SUM(C2:C6) = (B2*C2+B3*C3+B4*C4+B5*C5+B6*C6)/(C2+C3+C4+C5+C6)

ثم ، اضغط أدخل المفتاح ، تم حساب المتوسط ​​المرجح في وقت واحد ، راجع لقطة الشاشة:


المزيد من المقالات مع وظيفة SUMPRODUCT:

  • Countif قيمة محددة عبر أوراق عمل متعددة
  • لنفترض أن لدي العديد من أوراق العمل التي تحتوي على البيانات التالية ، والآن ، أريد الحصول على عدد تكرارات قيمة معينة "Excel" من أوراق عمل هذه الرسائل. كيف يمكنني حساب قيم محددة عبر أوراق عمل متعددة؟
  • حساب المتوسط ​​المرجح في إكسل
  • على سبيل المثال، لديك قائمة تسوق مع الأسعار والأوزان والمبالغ. يمكنك بسهولة حساب متوسط ​​السعر مع وظيفة أفيراج في إكسيل. ولكن ماذا لو متوسط ​​السعر المرجح؟ في هذه المقالة، سوف أعرض طريقة لحساب المتوسط ​​المرجح، وكذلك طريقة لحساب المتوسط ​​المرجح إذا استوفي معايير محددة في إكسيل.

أدوات إنتاجية Excel

شريط Excel (مع تثبيت Kutools لـ Excel)

تساعدك ميزات 300 المتقدمة على التميز من الحشد

هل ترغب في إكمال عملك اليومي بسرعة وبشكل مثالي؟ كوتولس ل إكسيل يجلب ميزات متقدمة قوية 300 (ضم المصنفات ، مجموع حسب اللون ، ومحتويات الخلايا المنقسمة ، وتاريخ التحويل ، وما إلى ذلك ...) وتوفير 80٪ من الوقت.

  • تساعدك سيناريوهات عمل 1500 على حل مشكلات 80٪ Excel.
  • قلل الآلاف من نقرات لوحة المفاتيح والماوس كل يوم ، وخفف عينيك ويديك المتعبين.
  • كن خبيرًا في Excel في دقائق 3. لم تعد بحاجة إلى تذكر أي صيغ مؤلمة ورموز VBA.
  • 30 يوم تجريبية مجانية غير محدودة. 60 يوم ضمان استعادة الاموال. ترقية مجانية ودعم لسنوات 2.

لقطة شاشة من Excel (مع تثبيت علامة تبويب Office)

تقديم علامات تبويب فعالة إلى Office (بما في ذلك Excel) ومثل Like Chrome و Firefox و New IE

  • تبويب أوفيس يزيد إنتاجيتك بنسبة 50٪ عند عرض وتحرير مستندات متعددة.
  • قلل من نقرات الماوس لك كل يوم ، قل وداعًا بيد الماوس.
  • ثانية واحدة للتبديل بين عشرات الوثائق المفتوحة!
Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.