Tipp: Andere Sprachen sind Google-Übersetzungen. Sie können die English Version dieses Links.
Einloggen
x
or
x
x
Registrieren
x

or

Wie erstelle ich Termine aus Excel-Daten?

Angenommen, Sie haben eine Tabelle mit Termindaten in einem Excel-Arbeitsblatt, wie im folgenden Screenshot gezeigt, möchten Sie diese Daten nun in den Outlook-Kalender importieren. Wie können Sie diesen Job schnell erledigen?

Exportieren von Excel-Daten nach Termin 1

Erstellen Sie Termine aus Excel-Daten mit VBA-Code


Erstellen Sie Termine aus Excel-Daten mit VBA-Code

Um Termine aus Excel-Daten zu erstellen, können Sie den folgenden VBA-Code anwenden:

1. Starten Sie Outlook und halten Sie die Maustaste gedrückt ALT + F11 Schlüssel zum Öffnen der Microsoft Visual Basic für Applikationen Fenster.

2. Klicken Sie Einsatz > Modul, und fügen Sie den folgenden Code in die Modul Fenster.

VBA-Code: Excel-Daten zum Termin importieren:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Immer noch in der Microsoft Visual Basic für Applikationen Klicken Sie im Fenster Tools > Referenzen auf dem Sprung Referenzen-Project1 Dialogfeld und überprüfen Microsoft Excel-Objektbibliothek Option von der Verfügbare Referenzen Listenfeld, siehe Screenshot:

Exportieren von Excel-Daten nach Termin 2

4. Dann klick OK Knopf drücken Sie jetzt F5 Schlüssel, um diesen Code auszuführen, und a Wählen Sie eine Datei aus Fenster wird angezeigt, wählen Sie bitte die Excel-Datei, die Sie in Outlook importieren möchten, siehe Screenshot:

Exportieren von Excel-Daten nach Termin 3

5. Und dann klick OK, eine Eingabeaufforderung erscheint wie folgt:

Exportieren von Excel-Daten nach Termin 4

6. Dann klick OKDie Excel-Daten wurden wie im folgenden Screenshot in den Kalender importiert:

Exportieren von Excel-Daten nach Termin 5



Kutools for Outlook

Mehr als 100 Erweiterte Funktionen für Outlook 2010, 2013, 2016, 2019 und 365

Screen-Kutools für Ausblick klein für Banner 201812

Weitere Funktionen | Gratis Download | Nur $ 39.00 für Hunderte von Funktionen

Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.
  • To post as a guest, your comment is unpublished.
    amiral · 2 days ago
    super cool il ya une erreur je la i rectifier mai apparament mes items colle pas mince



    olApp = Nothing ?
    xExcelApp.Quit