Tipp: Andere Sprachen sind Google-Übersetzungen. Sie können die English Version dieses Links.
Einloggen
x
or
x
x
Registrieren
x

or

Excel IF Funktion

Die IF-Funktion ist eine der einfachsten und nützlichsten Funktionen in einer Excel-Arbeitsmappe. Es führt einen einfachen logischen Test durch, der vom Vergleichsergebnis abhängt, und gibt einen Wert zurück, wenn ein Ergebnis WAHR ist, oder einen anderen Wert, wenn das Ergebnis FALSCH ist.


Syntax:

Die Syntax für die IF-Funktion in Excel lautet:

=IF (logical_test, [value_if_true], [value_if_false])

doc if Funktion 2


Argumente:

  • logical_test: Erforderlich. Dies ist die Bedingung, die Sie testen möchten.
  • value_if_true: Wahlweise. Ein bestimmter Wert, der zurückgegeben werden soll, wenn das Ergebnis von logical_test TRUE ist.
  • value_if_false: Wahlweise. Ein Wert, den Sie zurückgeben möchten, wenn das Ergebnis von logical_test FALSE ist.

Notizen:

1. Wenn value_if_true wurde weggelassen:

  • Wenn die value_if_true Argument wird in der IF-Funktion weggelassen, z. B. nur Komma nach logischem_test. Wenn die Bedingung erfüllt ist, wird Null zurückgegeben. Zum Beispiel: =IF(C2>100,, "Low ").
  • Wenn Sie eine leere Zelle anstelle der Null verwenden möchten, wenn die Bedingung erfüllt ist, müssen Sie im zweiten Parameter doppelte Anführungszeichen "" wie folgt eingeben: =IF(C2>100, "", "Low").
doc if Funktion 3 doc if Funktion 4

2. Wenn value_if_false wurde weggelassen:

  • Wenn die value_if_false Wenn der Parameter in der IF-Funktion weggelassen wird, wird FALSE zurückgegeben, wenn die angegebene Bedingung nicht erfüllt ist. Sowie: =IF(C2>100, "High").
  • Wenn Sie nach dem value_if_true-Argument ein Komma setzen, wird eine Null zurückgegeben, wenn die angegebene Bedingung nicht erfüllt ist. Sowie: =IF(C2>100, "High" ,).
  • Wenn Sie im dritten Parameter doppelte Anführungszeichen "" eingeben, wird eine leere Zelle zurückgegeben, wenn die Bedingung nicht erfüllt ist. Sowie: =IF(C2>100, "High" , "").
doc if Funktion 5 doc if Funktion 6 doc if Funktion 7

Zurück:

Beim Testen auf eine bestimmte Bedingung wird der entsprechende Wert zurückgegeben, den Sie für TRUE oder FALSE angeben.


Beispiele:

Beispiel 1: Verwenden einer einfachen IF-Funktion für Zahlen

Angenommen, Sie möchten eine Liste von Werten testen. Wenn der Wert größer als ein bestimmter Wert 100 ist, wird ein Text "Gut" angezeigt. Andernfalls wird ein Text "Schlecht" zurückgegeben.

Geben Sie die folgende Formel ein, und Sie erhalten das unten stehende Ergebnis nach Bedarf.

=IF(B2>100,"Good","Bad")

doc if Funktion 8


Beispiel 2: Verwendung der IF-Funktion für Textwerte

Groß- / Kleinschreibung 1: IF-Funktion für Textwerte ohne Berücksichtigung der Groß- / Kleinschreibung:

Hier habe ich eine Tabelle mit einer Liste von Aufgaben und Abschlussstatus. Jetzt möchte ich wissen, welche Aufgaben ausgeführt werden müssen und welche nicht. Wenn der Text in Spalte C vollständig ist, wird "Nein" angezeigt, andernfalls wird "Ja" zurückgegeben.

Bitte wenden Sie die folgende Formel an. Jetzt gibt die Zelle "Nein" zurück, wenn der Text in Spalte C als "erledigt" angezeigt wird, unabhängig davon, ob es sich um Groß- oder Kleinbuchstaben handelt. Wenn ein anderer Text in Spalte C angezeigt wird, wird "Ja" zurückgegeben. Siehe Screenshot:

=IF(C2="completed", "No", "Yes")

doc if Funktion 9

Groß- / Kleinschreibung 2: IF-Funktion für Textwerte mit Groß- / Kleinschreibung:

Um die Textwerte mit Groß- und Kleinschreibung zu testen, sollten Sie die IF-Funktion mit der EXACT-Funktion kombinieren. Wenden Sie die folgende Formel an, damit nur der Text mit der genauen Übereinstimmung erkannt wird und Sie das folgende Ergebnis erhalten, wie Sie möchten:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

doc if Funktion 10

Fall 3: IF-Funktion für Textwerte mit teilweiser Übereinstimmung:

Manchmal müssen Sie die Zellenwerte auf der Basis von Teiltext überprüfen. In diesem Fall sollten Sie die Funktionen IF, ISNUMBER und SEARCH zusammen verwenden.

Wenn Sie beispielsweise die Zellen überprüfen möchten, die den Text "comp" enthalten, und dann die entsprechenden Werte zurückgeben möchten, wenden Sie die folgende Formel an. Und sie erhalten das ergebnis wie folgt screenshot gezeigt:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

doc if Funktion 11

Anmerkungen:

  • 1. Die Suchfunktion wird für Text angewendet, bei dem die Groß- und Kleinschreibung nicht berücksichtigt wird. Wenn Sie den Text mit der Groß- und Kleinschreibung prüfen möchten, müssen Sie die Suchfunktion durch die Suchfunktion ersetzen. So was:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Die Textwerte als Parameter in den IF-Formeln müssen Sie in "doppelte Anführungszeichen" setzen.

Beispiel 3: Verwendung der IF-Funktion für Datumswerte

Fall 1: IF-Funktion für Daten, um Daten mit einem bestimmten Datum zu vergleichen:

Wenn Sie Daten vergleichen möchten, um zu überprüfen, ob sie größer oder kleiner als ein bestimmtes Datum sind, kann die IF-Funktion Ihnen ebenfalls einen Gefallen tun. Da die IF-Funktion kein Datumsformat erkennen kann, sollten Sie eine DATEVALUE-Funktion damit kombinieren.

Bitte wenden Sie diese Formel an, wenn das Datum größer als 4 / 15 / 2019 ist, wird ein "Ja" zurückgegeben, andernfalls gibt die Formel einen "Nein" -Text zurück, siehe Screenshot:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

doc if Funktion 12

Text: In der obigen Formel können Sie die Zellreferenz direkt verwenden, ohne auch die Funktion DATEVALUE zu verwenden. So was: =IF(D4>$D$1, "Yes", "No").

doc if Funktion 13

Fall 2: IF-Funktion für Daten zum Überprüfen von Daten ist größer oder kleiner als 30-Tage:

Wenn Sie die Daten identifizieren möchten, die größer oder kleiner als 30 Tage ab dem aktuellen Datum sind, können Sie die Funktion HEUTE mit der Funktion WENN kombinieren.

Bitte geben Sie diese Formel ein:

Identifizieren Sie das Datum, das älter als 30 Tage ist: =IF(TODAY()-C4>30,"Older date","")

Identifizieren Sie das Datum, das größer als 30 Tage ist: =IF(C4-TODAY()>30, "Future date", "")

doc if Funktion 14 doc if Funktion 15

Hinweis: Wenn Sie beide Ergebnisse in einer Spalte zusammenfassen möchten, müssen Sie eine verschachtelte IF-Funktion wie folgt verwenden:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

doc if Funktion 16


Beispiel 4: Verwenden der IF-Funktion zusammen mit der AND-, OR-Funktion

Es ist eine übliche Verwendung für uns, die Funktionen IF, AND, OR in Excel miteinander zu kombinieren.

Fall 1: Verwenden der IF-Funktion mit AND-Funktionen, um zu überprüfen, ob alle Bedingungen erfüllt sind:

Ich möchte überprüfen, ob alle von mir festgelegten Bedingungen erfüllt sind, z. B .: B4 ist Rot, C4 ist Klein und D4> 200. Wenn alle Bedingungen TURE sind, markieren Sie das Ergebnis mit „Ja“. Wenn eine der beiden Bedingungen FALSCH ist, geben Sie "Nein" zurück.

Wenden Sie diese Formel an und Sie erhalten das Ergebnis wie folgt:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

doc if Funktion 17

Fall 2: Die Verwendung der IF-Funktion mit OR-Funktionen, um eine der Bedingungen zu überprüfen, ist wahr:

Sie können auch IF- und OR-Funktionen verwenden, um zu überprüfen, ob eine der Bedingungen zutrifft. Beispielsweise möchte ich feststellen, ob die Zelle in Spalte B den Text "Blau" oder "Rot" enthält, wenn Text in Spalte B vorhanden ist. Ja wird angezeigt, andernfalls wird Nein zurückgegeben.

Hier sollten Sie diese Formel anwenden, und das folgende Ergebnis wird angezeigt:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

doc if Funktion 18

Fall 3: Verwenden der IF-Funktion mit AND- und OR-Funktionen zusammen:

In diesem Beispiel werde ich die WENN-Funktion gleichzeitig mit UND- und ODER-Funktionen kombinieren. Angenommen, Sie sollten die folgenden Bedingungen prüfen:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Wenn eine der oben genannten Bedingungen erfüllt ist, wird eine Übereinstimmung zurückgegeben, andernfalls Nein.

Verwenden Sie bitte diese Formel, und Sie erhalten das folgende Ergebnis, wie Sie benötigen:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

doc if Funktion 19


Beispiel 5: Verwenden der verschachtelten IF-Funktion

Mit der IF-Funktion wird eine Bedingung getestet und ein Wert zurückgegeben, wenn die Bedingung erfüllt ist, und ein anderer Wert, wenn sie nicht erfüllt ist. In manchen Fällen müssen Sie jedoch mehrere Bedingungen gleichzeitig prüfen und unterschiedliche Werte zurückgeben. Sie können diesen Job mit der Option "Verschachteltes IF" lösen.

Eine verschachtelte IF-Anweisung, die mehrere IF-Bedingungen kombiniert, bedeutet, eine IF-Anweisung in eine andere IF-Anweisung einzufügen und diesen Vorgang mehrmals zu wiederholen.

Die Syntax für die geschachtelte WENN-Funktion in Excel lautet:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

TextHinweis: In Excel 2007 und späteren Versionen können Sie bis zu 64-IF-Funktionen in einer Formel verschachteln. In Excel 2003 und früheren Versionen können nur 7-geschachtelte IF-Funktionen verwendet werden.

Fall 1: Verschachtelte IF-Funktion zum Überprüfen mehrerer Bedingungen:

Eine klassische Verwendung der geschachtelten WENN-Funktion besteht darin, jedem Schüler anhand seiner Punktzahl eine Note zuzuweisen. Wenn Sie beispielsweise eine Tabelle mit Schülern und ihren Prüfungsergebnissen haben, möchten Sie die Ergebnisse jetzt mit den folgenden Bedingungen klassifizieren:

doc if Funktion 20

Wenden Sie diese Formel an und Sie erhalten das folgende Ergebnis, wenn die Punktzahl größer oder gleich 90 ist, die Note „Vorzüglich“ ist, wenn die Punktzahl größer oder gleich 80 ist, die Note „Gut“ ist, wenn die Punktzahl ist ist größer oder gleich 60, die Note ist "Mittel", ansonsten ist die Note "Schlecht".

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

doc if Funktion 21

Erklärung der obigen Formel:

doc if Funktion 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Fall 2: Verschachtelte WENN-Funktion zur Preisberechnung anhand der Menge:

Die geschachtelte WENN-Funktion kann auch verwendet werden, um den Produktpreis basierend auf der Menge zu berechnen.

Beispielsweise möchten Sie den Kunden eine Preisunterbrechung basierend auf der Menge, der Menge, die sie kaufen, und dem Rabatt gewähren, den sie erhalten. Siehe Abbildung unten.

doc if Funktion 23

Da der Gesamtpreis gleich der Menge ist, multiplizieren Sie den Preis mit der angegebenen Menge und dem von geschachtelten Ifs zurückgegebenen Wert. Bitte benutzen Sie diese Formel:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

doc if Funktion 24

Text: Sie können auch die Zellreferenzen verwenden, um die statischen Preisnummern zu ersetzen. Wenn sich die Quelldaten ändern, sollten Sie die Formel nicht aktualisieren müssen. Verwenden Sie diese Formel: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

doc if Funktion 25

Tipps: Mit der IF-Funktion zum Erstellen eines Tests können Sie folgende logische Operatoren verwenden:

Operator Bedeutung Beispiel Beschreibung
> Größer als =IF(A1>10, "OK",) Wenn die Zahl in der Zelle A1 größer als 10 ist, gibt die Formel "OK" zurück. Andernfalls wird 0 zurückgegeben.
< Weniger als =IF(A1<10, "OK", "") Wenn die Zahl in Zelle A1 kleiner als 10 ist, gibt die Formel "OK" zurück; Andernfalls wird eine leere Zelle zurückgegeben.
> = Größer als oder gleich wie =IF(A1>=10, "OK", "Bad") Wenn die Zahl in der Zelle A1 größer oder gleich 10 ist, wird "OK" zurückgegeben. Andernfalls wird "Bad" angezeigt.
<= Gleich oder kleiner als =IF(A1<=10, "OK", "No") Wenn die Zahl in der Zelle A1 kleiner oder gleich 10 ist, wird "OK" zurückgegeben. Andernfalls wird "Nein" zurückgegeben.
= Gleich =IF(A1=10, "OK", "No") Wenn die Zahl in Zelle A1 gleich 10 ist, wird "OK" zurückgegeben. Andernfalls wird "Nein" angezeigt.
<> Nicht gleichzusetzen mit =IF(A1<>10, "No", "OK") Wenn die Zahl in der Zelle A1 nicht 10 entspricht, gibt die Formel "Nein" zurück. sonst - "OK".

Excel-Produktivitätstools

Multifunktionsleiste von Excel (mit installierten Kutools für Excel)

Mit den erweiterten 300-Funktionen können Sie sich von der Masse abheben

Möchten Sie Ihre tägliche Arbeit schnell und perfekt erledigen? Kutools for Excel bringt 300 leistungsstarke erweiterte Funktionen (Arbeitsmappen kombinieren, nach Farbe summieren, Zelleninhalt teilen, Datum konvertieren usw.) und spart 80% Zeit.

  • Entwickelt für 1500-Arbeitsszenarien, hilft Ihnen bei der Lösung von 80% Excel-Problemen.
  • Reduzieren Sie täglich Tausende von Tastatur- und Mausklicks und entlasten Sie Ihre müden Augen und Hände.
  • Werden Sie ein Excel-Experte in 3-Minuten. Sie müssen sich keine schmerzhaften Formeln und VBA-Codes mehr merken.
  • 30-Tag unbegrenzte kostenlose Testversion. Geld-zurück-Garantie für 60-Tage. Kostenloses Upgrade und Support für 2-Jahre.

Screenshot von Excel (mit installiertem Office-Tab)

Bringt effiziente Tabs nach Office (einschließlich Excel), genau wie Chrome, Firefox und New IE

  • Office Tab Steigert Ihre Produktivität um 50% beim Anzeigen und Bearbeiten mehrerer Dokumente.
  • Reduzieren Sie täglich Hunderte von Mausklicks, verabschieden Sie sich von der Maushand.
  • Eine Sekunde, um zwischen Dutzenden offener Dokumente zu wechseln!
Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.