How to move specific files from one folder to another in Excel?

Supposing, I have a large folder which contains kinds of files, such as docx, jpg, xlsx, etc as following screenshot shown. Now, I want to move some specific file types from the folder to another new folder without moving one by one manually. Do you have any good ideas to solve this task in Excel?

Move specific files from one folder to another folder with VBA code

Move specific files from one folder to another folder with VBA code

To move all the specific types of files from one folder to another as quickly as you want, the following VBA code may help you, please do as this:

1. Hold down ALT + F11 keys to open the Microsoft Visual Basic for Applications window.

2. Click Insert > Module, and paste the following code in the Module Window.

VBA code: Move specific types of files from one folder to another one:

Sub MoveFiles()
'Updateby Extendoffice
    Dim xFd As FileDialog
    Dim xTFile As String
    Dim xExtArr As Variant
    Dim xExt As Variant
    Dim xSPath As String
    Dim xDPath As String
    Dim xSFile As String
    Dim xCount As Long
    Set xFd = Application.FileDialog(msoFileDialogFolderPicker)
    xFd.Title = "Please select the original folder:"
    If xFd.Show = -1 Then
        xSPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xSPath, 1) <> "\" Then xSPath = xSPath + "\"
    xFd.Title = "Please select the destination folder:"
    If xFd.Show = -1 Then
        xDPath = xFd.SelectedItems(1)
    Else
        Exit Sub
    End If
    If Right(xDPath, 1) <> "\" Then xDPath = xDPath + "\"
    xExtArr = Array("*.xlsx*", "*.jpg")
    For Each xExt In xExtArr
        xTFile = Dir(xSPath & xExt)
        Do While xTFile <> ""
            xSFile = xSPath & xTFile
            FileCopy xSFile, xDPath & xTFile
            Kill xSFile
            xTFile = Dir
            xCount = xCount + 1
        Loop
    Next
    MsgBox "Total number of moved files is: " & xCount, vbInformation, "Kutools for Excel"
End Sub

Note: In the above code, "*.xlsx*", "*.jpg" in the script: xExtArr = Array("*.xlsx*", "*.jpg") are the file types you want to move, you can change them to others or add other file types as you need.

3. Then press F5 key to run this code, and a window popped out to remind you to select the original folder where you want to move the files from, see screenshot:

4. Then click OK, and another window is popped up, please choose the destination folder where you want to move the files to, see screenshot:

5. And then click OK, a prompt box will pop out to remind you how many files have been moved, close it, and you can see the specific jpg, xlsx files have been moved into the specified folder, see screenshot: