How to run multiple macros from right click menu in Excel?

If there are multiple vba macros in your workbook, you should open the VBA window and then choose the macro when you need to run the code. In this article, I would like to talk about how to run macros from right click menu to make your work more efficient as left screenshot shown.

Run multiple macros from right click menu with VBA codes

Run multiple macros from right click menu with VBA codes

To run the macro codes within a workbook from the right click menu, the following steps may help you, please do as this:

1. Hole down the Alt + F11 keys to open the Microsoft Visual Basic for Applications window.

2. Then, double click ThisWorkbook in the left Project pane, and then copy and paste the below VBA code into the blank module.

Private Sub Workbook_Open()
Run "LoadMacro"
End Sub
Private Sub Workbook_Activate()
Run "LoadMacro"
End Sub
Private Sub Workbook_Deactivate()
Run "ClearMacro"
End Sub
Private Sub Workbook_BeforeClose(Cancel As Boolean)
Run "ClearMacro"
ThisWorkbook.Save
End Sub

3. Still in the Microsoft Visual Basic for Applications window, please click Insert > Module, and paste the following code into this module.

Private Sub LoadMacro()
Dim xArrMenu As Variant
Dim xStrLine, xSreBtnName As String
Dim xObjCBCF, xObjCntrAll As CommandBarControl
Dim xObjCBCs As CommandBars
Dim xObjCBBtn As CommandBarButton
Dim xIntLine, xFNum As Integer
Dim xObjComponent As Object
Run "ClearMacro"
Set xObjCBCF = Application.CommandBars("Cell").Controls.Add(msoControlPopup, before:=1)
xObjCBCF.Caption = " Run Macro "
xObjCBCF.BeginGroup = False
For Each xObjComponent In ActiveWorkbook.VBProject.VBComponents
    If xObjComponent.Type = 1 Then
        For xIntLine = 1 To xObjComponent.CodeModule.CountOfLines
        xStrLine = xObjComponent.CodeModule.Lines(xIntLine, 1)
        xStrLine = Trim(xStrLine)
            If (InStr(xStrLine, "()") > 0) And (Left(xStrLine, 11) = "Private Sub" Or Left(xStrLine, 3) = "Sub") Then
            xSreBtnName = ""
            If "Private Sub" = Left(xStrLine, 11) Then
                xSreBtnName = Trim(Mid(xStrLine, 12, InStr(xStrLine, "()") - 12))
            ElseIf "Sub" = Left(xStrLine, 3) Then
               xSreBtnName = Trim(Mid(xStrLine, 4, InStr(xStrLine, "()") - 4))
            End If
            If xSreBtnName <> "" And xSreBtnName <> "RightClickReset" And xSreBtnName <> "LoadMacro" And xSreBtnName <> "ActionMacro" Then
                Set xObjCBBtn = xObjCBCF.Controls.Add
                With xObjCBBtn
                    .FaceId = 186
                    .Style = msoButtonIconAndCaption
                    .Caption = xSreBtnName
                    .OnAction = "ActionMacro"
                End With
            End If
            End If
        Next xIntLine
    End If
Next xObjComponent
End Sub
Private Sub ClearMacro()
On Error Resume Next
CommandBars("Cell").Controls(" Run Macro ").Delete
Err.Clear
CommandBars("Cell").Reset
End Sub
Private Sub ActionMacro()
On Error GoTo Err1
With Application
Run .CommandBars("Cell").Controls(1).Controls(.Caller(1)).Caption
End With
Exit Sub
Err1:
    MsgBox "Invalid"
End Sub

4. After pasting the codes, then click Tools > References, and a References-VBAProject dialog box is displayed, and then check Microsoft Visual Basic for Applications Extensibility 5.3 option in the Available References list box, see screenshot:

5. Then click OK to exit the dialog, now, you should save this workbook as Excel Macro-Enabled Workbook format, see screenshot:

6. At last, please restart the workbook to take the codes effect, and now, when you right click a cell, a Run Macro option is inserted into the right click menu, and all macros in your workbook are listed in submenu as following screenshot:

7. Then you can run the code just by clicking it.