This method will introduce a VBA to automatically expand all folders on the Navigation Pane when you start Outlook. Please apply this VBA as follows:

1. Press Alt + F11 keys simultaneously to open the Microsoft Visual Basic for Applications window.

2. Expand the Project 1 and Microsoft Outlook Objects in the Project pane, double click to open the ThisOutlookSession window, and then paste below VBA code into it.

VBA: Automatically expand all folders in Outlook

Private Sub Application_Startup()
  'Update by ExtendOffice 2022/08/03
  ExpandAllFolders
End Sub

Public Sub ExpandAllFolders()
  Dim xNameSpace As Outlook.NameSpace
  Dim xFlds As Outlook.Folders
  Dim xCurrFld As Outlook.MAPIFolder
  Dim xFld As Outlook.MAPIFolder
  Dim xExpandDefaultStoreOnly As Boolean
  Dim xModule As NavigationModule
  On Error Resume Next
  xExpandDefaultStoreOnly = False
  Set xNameSpace = Application.Session
  Set xModule = Application.ActiveExplorer.NavigationPane.CurrentModule
  Set xCurrFld = Application.ActiveExplorer.CurrentFolder
  If xExpandDefaultStoreOnly = True Then
    Set xFld = xNameSpace.GetDefaultFolder(olFolderInbox)
    Set xFld = xFld.Parent
    Set xFlds = xFld.Folders
    LoopFolders xFlds, True
  Else
    LoopFolders xNameSpace.Folders, True
    LoopFolders xNameSpace.Folders, False
  End If
  DoEvents
  Set Application.ActiveExplorer.NavigationPane.CurrentModule = xModule
  Set Application.ActiveExplorer.CurrentFolder = xCurrFld
  Set xNameSpace = Nothing
  Set xModule = Nothing
  Set xCurrFld = Nothing
End Sub

Private Sub LoopFolders(Flds As Outlook.Folders, ByVal All As Boolean)
  Dim xFld As Outlook.MAPIFolder
  On Error Resume Next
  For Each xFld In Flds
    Select Case All
      Case True
        If xFld.DefaultItemType = olMailItem Then
          Set Application.ActiveExplorer.CurrentFolder = xFld
          DoEvents
          If xFld.Folders.Count > 0 Then
            LoopFolders xFld.Folders, All
          End If
        End If
      Case False
        Set Application.ActiveExplorer.CurrentFolder = xFld
        DoEvents
        If xFld.Folders.Count > 0 Then
          LoopFolders xFld.Folders, All
        End If
    End Select
  Next
End Sub

3. Save the code and close the Microsoft Visual Basic for Applications window.

From now on, when restarting Outlook, all folders will be automatically expanded in Outlook. Note: This VBA cannot open the collapsed search folders when restarting Outlook.

Delete multiple folders in bulk in Outlook

Delete all duplicate emails from a mail folder in Outlook