Consejo: Otros idiomas son traducidos por Google. Puedes visitar el English versión de este enlace.
Iniciar sesión
x
or
x
x
Suscríbete
x

or

Excel IF función

La función IF es una de las funciones más simples y útiles en el libro de Excel. Realiza una prueba lógica simple que, según el resultado de la comparación, devuelve un valor si el resultado es VERDADERO u otro valor si el resultado es FALSO.


Sintaxis:

La sintaxis de la función IF en Excel es:

=IF (logical_test, [value_if_true], [value_if_false])

doc si función 2


Argumentos:

  • logical_test: Requerido. Es la condición que desea probar.
  • value_if_true: Opcional. Un valor específico que desea que se devuelva si el resultado de prueba_lógica es VERDADERO.
  • value_if_false: Opcional. Un valor que desea que se devuelva si el resultado de prueba_lógica es FALSO.

Notas:

1. Si value_if_true se omite:

  • Si la línea value_if_true el argumento se omite en la función IF, como solo una coma después de la prueba_lógica, devolverá cero cuando se cumpla la condición. Por ejemplo: =IF(C2>100,, "Low ").
  • Si desea usar una celda en blanco en lugar del cero si se cumple la condición, debe ingresar comillas dobles "" en el segundo parámetro, como esto: =IF(C2>100, "", "Low").
doc si función 3 doc si función 4

2. Si value_if_false se omite:

  • Si la línea value_if_false el parámetro se omite en la función IF, devolverá un FALSO cuando no se cumple la condición especificada. Como: =IF(C2>100, "High").
  • Si coloca una coma después del argumento value_if_true, devolverá un cero cuando no se cumpla la condición especificada. Como: =IF(C2>100, "High" ,).
  • Si ingresa comillas dobles en el tercer parámetro, se devolverá una celda vacía si no se cumple la condición. Como: =IF(C2>100, "High" , "").
doc si función 5 doc si función 6 doc si función 7

Regreso:

Prueba de una condición específica, devuelve el valor correspondiente que proporcionó para VERDADERO o FALSO.


Ejemplos:

Ejemplo 1: Uso de una función IF simple para números

Por ejemplo, suponiendo que desea probar una lista de valores, si el valor es mayor que un valor específico 100, se muestra un texto "Bueno"; de lo contrario, se devuelve un texto "Malo".

Ingrese la siguiente fórmula, y obtendrá el resultado que se muestra a continuación según lo necesite.

=IF(B2>100,"Good","Bad")

doc si función 8


Ejemplo 2: Uso de la función IF para valores de texto

Case 1: función IF para valores de texto con mayúsculas y minúsculas:

Aquí, tengo una tabla con una lista de Tareas y estado de finalización, ahora, quiero saber qué tareas deben continuar y cuáles no. Cuando se complete el texto en la Columna C, se mostrará "No", de lo contrario, se devolverá "Sí".

Aplique la siguiente fórmula, ahora, la celda devolverá "No" cuando el texto en la columna C se muestre como "completado", sin importar que esté en mayúsculas o minúsculas; Si otro texto en la columna C, se devolverá "Sí". Ver captura de pantalla:

=IF(C2="completed", "No", "Yes")

doc si función 9

Case 2: función IF para valores de texto con mayúsculas y minúsculas:

Para probar los valores de texto con mayúsculas y minúsculas, debe combinar la función IF con la función EXACTA, aplique la siguiente fórmula, entonces solo se reconocerá el texto con la coincidencia exacta, y obtendrá el resultado que desea a continuación:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

doc si función 10

Case 3: función IF para valores de texto con coincidencia parcial:

A veces, necesita verificar los valores de celda basados ​​en texto parcial, en este caso, debe usar las funciones IF, ISNUMBER y SEARCH juntas.

Por ejemplo, si desea verificar las celdas que contienen el texto "comp" y luego devolver los valores correspondientes, aplique la siguiente fórmula. Y obtendrá el resultado como se muestra a continuación en la captura de pantalla:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

doc si función 11

Notas:

  • 1. La función de BÚSQUEDA se aplica para el texto con mayúsculas y minúsculas, si desea verificar el texto con mayúsculas y minúsculas, debe reemplazar la función de BÚSQUEDA con la función FINALIZAR. Me gusta esto:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Los valores de texto como parámetros en las fórmulas IF, debe encerrarlos entre "comillas dobles".

Ejemplo 3: Uso de la función IF para valores de fecha

Caso 1: función IF para fechas para comparar fechas con una fecha específica:

Si desea comparar fechas para verificar si son mayores o menores que una fecha específica, la función IF también puede hacerle un favor. Como la función IF no puede reconocer un formato de fecha, debe combinar una función DATEVALUE con ella.

Aplique esta fórmula, cuando la fecha sea mayor que 4 / 15 / 2019, se devolverá un “Sí”; de lo contrario, la fórmula devolverá un texto “No”, vea la captura de pantalla:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

doc si función 12

Nota: En la fórmula anterior, puede usar la referencia de celda directamente sin usar la función DATEVALUE también. Me gusta esto: =IF(D4>$D$1, "Yes", "No").

doc si función 13

Caso 2: la función IF para fechas para verificar fechas es mayor o menor que los días 30:

Si desea identificar las fechas que son mayores o menores que 30 días a partir de la fecha actual, puede combinar la función HOY con la función IF.

Por favor ingrese esta fórmula:

Identifique la fecha anterior a los días 30: =IF(TODAY()-C4>30,"Older date","")

Identifique la fecha mayor a 30 días: =IF(C4-TODAY()>30, "Future date", "")

doc si función 14 doc si función 15

Nota: Si desea poner los dos resultados en una columna, necesita usar una función IF anidada como esta:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

doc si función 16


Ejemplo 4: Uso de la función IF con AND, OR función conjunta

Es un uso común para nosotros combinar las funciones IF, AND, OR en Excel.

Case 1: uso de la función IF con las funciones AND para verificar si todas las condiciones son verdaderas:

Quiero verificar si se cumplen todas las condiciones que establecí, como: B4 es rojo, C4 es pequeño y D4> 200. Si todas las condiciones son TURE, marque el resultado como "Sí"; Si cualquiera de las condiciones es FALSA, devuelva "No".

Aplique esta fórmula y obtendrá el resultado como se muestra a continuación:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

doc si función 17

Caso 2: el uso de la función IF con las funciones OR para verificar cualquiera de las condiciones es verdadero:

También puede usar las funciones IF y OR para verificar si alguna de las condiciones es verdadera, por ejemplo, quiero identificar si la celda en la columna B contiene el texto "Azul" o "Rojo", si hay algún texto en la columna B, Sí se muestra, de lo contrario, No se devuelve.

Aquí, debes aplicar esta fórmula, y se mostrará el siguiente resultado:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

doc si función 18

Case 3: usando la función IF con las funciones AND y OR juntas:

En este ejemplo, combinaré la función IF con ambas funciones AND & OR al mismo tiempo. Suponiendo que, debe comprobar las siguientes condiciones:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Si se cumple alguna de las condiciones anteriores, se devuelve una coincidencia; de lo contrario, No.

Utilice esta fórmula y obtendrá el siguiente resultado que necesita:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

doc si función 19


Ejemplo 5: Uso de la función IF anidada

La función IF se utiliza para probar una condición y devolver un valor si se cumple la condición y otro valor si no se cumple. Pero, a veces, debe comprobar más de una condición al mismo tiempo y devolver valores diferentes, puede usar Nested IF para resolver este trabajo.

Una declaración IF anidada que combina múltiples condiciones IF, significa colocar una declaración IF dentro de otra declaración IF y repetir ese proceso varias veces.

La sintaxis de la función IF anidada en Excel es:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

Nota: En Excel 2007 y versiones posteriores, puede anidar las funciones 64 IF en una fórmula, y en Excel 2003 y versiones anteriores, solo se pueden usar las funciones IF anidadas de 7.

Caso 1: función de IF anidada para verificar múltiples condiciones:

Un uso clásico de la función IF anidado es asignar una calificación de letras para cada estudiante en función de sus calificaciones. Por ejemplo, tiene una tabla con los alumnos y sus calificaciones en los exámenes, ahora desea clasificar las calificaciones con las siguientes condiciones:

doc si función 20

Aplique esta fórmula y obtendrá el siguiente resultado, si la puntuación es mayor o igual a 90, la calificación es "Excelente", si la puntuación es mayor o igual a 80, la calificación es "Buena", si la puntuación es mayor o igual a 60, el grado es "Medio", de lo contrario, el grado es "Pobre".

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

doc si función 21

Explicación de la fórmula anterior:

doc si función 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Case 2: función IF anidada para calcular el precio en función de la cantidad:

La función Nested IF también se puede utilizar para calcular el precio del producto según la cantidad.

Por ejemplo, desea proporcionar a los clientes un margen de precio basado en la cantidad, más cantidad que compran, más descuento que obtendrán como se muestra en la siguiente captura de pantalla.

doc si función 23

Como el precio total es igual a la cantidad, multiplique el precio, de modo que debe multiplicar la cantidad especificada por el valor devuelto por los If anidados. Por favor, utilice esta fórmula:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

doc si función 24

Nota: También puede usar las referencias de celdas para reemplazar los números de precios estáticos, cuando los datos de origen cambien, no debería necesitar actualizar la fórmula, use esta fórmula: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

doc si función 25

Consejos: Al usar la función IF para construir una prueba, puede usar los siguientes operadores lógicos:

Operador Sentido Ejemplo Descripción
> Más que =IF(A1>10, "OK",) Si el número en la celda A1 es mayor que 10, la fórmula devuelve "OK"; De lo contrario se devuelve 0.
< Menos que =IF(A1<10, "OK", "") Si el número en la celda A1 es menor que 10, la fórmula devuelve "OK"; De lo contrario, se devuelve una celda vacía.
> = Mayor qué o igual a =IF(A1>=10, "OK", "Bad") Si el número en la celda A1 es mayor o igual que 10, devolverá "OK"; de lo contrario, se muestra "Bad".
<= Menos que o igual a =IF(A1<=10, "OK", "No") Si el número en la celda A1 es menor o igual que 10, devuelve "OK"; de lo contrario, se devuelve "No".
= Igual a =IF(A1=10, "OK", "No") Si el número en la celda A1 es igual a 10, devuelve "OK"; de lo contrario, muestra "No".
<> No igual a =IF(A1<>10, "No", "OK") Si el número en la celda A1 no es igual a 10, la fórmula devuelve "No"; de lo contrario - "OK".

Excel herramientas de productividad

Cinta de Excel (con Kutools para Excel instalado)

Las características avanzadas de 300 lo ayudan a sobresalir de la multitud

¿Te gustaría completar tu trabajo diario de forma rápida y perfecta? Kutools for Excel trae funciones potentes y avanzadas de 300 (Combine libros, suma por color, dividir contenido de celdas, convertir fecha, etc.) y ahorre tiempo de 80.

  • Diseñado para los escenarios de trabajo 1500, le ayuda a resolver problemas de 80% Excel.
  • Reduzca miles de clics de teclado y mouse todos los días, alivie sus ojos y manos cansados.
  • Conviértete en un experto en Excel en minutos 3. Ya no es necesario recordar ninguna fórmula dolorosa y códigos VBA.
  • 60-day prueba gratuita ilimitada. 60 días de garantía de devolución de dinero. Actualización gratuita y soporte para años 2.

Captura de pantalla de Excel (con la pestaña Office instalada)

Trae fichas eficientes a Office (incluye Excel), igual que Chrome, Firefox y nuevo IE

  • Office Tab Aumenta su productividad en un 50% al ver y editar varios documentos.
  • Reduzca cientos de clics del mouse para usted todos los días, despídase de la mano del mouse.
  • ¡Un segundo para cambiar entre docenas de documentos abiertos!
Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.