As cookies axúdanos a entregar os nosos servizos. Ao usar os nosos servizos, acepta o noso uso das cookies.
Consello: outros idiomas están traducidos a Google. Podes visitar o English versión desta ligazón.
Iniciar sesión
x
or
x
x
Register
x

or

Como crear unha cita a partir de datos de Excel?

Supoñendo, ten unha táboa de datos de cita nunha folla de cálculo de Excel como se mostra na seguinte imaxe, agora, quere importar estes datos no calendario de Outlook. Como podería lidiar con este traballo rapidamente?

doc export excel datos á cita 1

Crea citas de datos de Excel con código VBA


Crea citas de datos de Excel con código VBA

Para crear citas de datos de Excel, pode aplicar o seguinte código VBA, faga o seguinte:

1. Inicia Outlook e mantén premido o ALT + F11 chaves para abrir a Microsoft Visual Basic para aplicacións fiestra.

2. Prema Inserir > Módulos, e pegue o seguinte código no Módulos Fiestra.

Código VBA: Importar datos de Excel para a cita:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Aínda no Microsoft Visual Basic para aplicacións fiestra, prema en ferramentas > References para ir ao Referencias-Project1 caixa de diálogo e verificación Biblioteca de obxectos de Microsoft Excel opción dende o Referencias dispoñibles caixa de lista, vexa a captura de pantalla:

doc export excel datos á cita 2

4. A continuación, fai clic en OK botón, agora, prema F5 clave para executar este código e a Selecciona un ficheiro aparece a fiestra, seleccione o ficheiro de Excel que quere importar a Outlook, vexa a captura de pantalla:

doc export excel datos á cita 3

5. E logo faga clic en OK, aparece unha caixa de seguimento do seguinte xeito:

doc export excel datos á cita 4

6. A continuación, fai clic en OK, os datos de Excel importáronse no calendario seguindo a seguinte captura de pantalla:

doc export excel datos á cita 5



Kutools para Outlook

Máis de 100 Funcións avanzadas para Outlook 2010, 2013, 2016, 2019 e 365

captura de pantalla kutools para pequenas perspectivas para a bandeira 201812

Máis recursos | Descarga gratuíta | Só $ 39.00 por centos de funcións

Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.