Suggerimento: le altre lingue sono tradotte da Google. Puoi visitare il English versione di questo link.
Log In
x
or
x
x
Registrati
x

or

Come creare un appuntamento da dati Excel?

Supponendo, hai una tabella di dati sugli appuntamenti in un foglio di lavoro Excel come mostrato nella seguente schermata, ora, vuoi importare questi dati nel calendario di Outlook. Come hai potuto affrontare questo lavoro rapidamente?

documento esporta dati excel per appuntamento 1

Crea appuntamenti da dati Excel con codice VBA


Crea appuntamenti da dati Excel con codice VBA

Per creare appuntamenti da dati Excel, puoi applicare il seguente codice VBA, per favore fai come segue:

1. Avvia Outlook e tieni premuto il ALT + F11 chiavi per aprire il Microsoft Visual Basic, Applications Edition finestra.

2. Clic inserire > Moduloe incollare il seguente codice nel Modulo Finestra.

Codice VBA: importare i dati excel nell'appuntamento:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Ancora nel Microsoft Visual Basic, Applications Edition finestra, fare clic Strumenti > Referenze per andare al Riferimenti-Project1 finestra di dialogo e controllare Libreria di oggetti di Microsoft Excel opzione dal Riferimenti disponibili casella di riepilogo, vedi screenshot:

documento esporta dati excel per appuntamento 2

4. Quindi fare clic OK pulsante, ora, premere F5 chiave per eseguire questo codice e a Seleziona un file viene visualizzata la finestra, selezionare il file Excel che si desidera importare in Outlook, vedere screenshot:

documento esporta dati excel per appuntamento 3

5. E poi clicca OK, viene visualizzata una finestra di messaggio come segue:

documento esporta dati excel per appuntamento 4

6. Quindi fare clic OK, i dati Excel sono stati importati nel calendario come mostrato di seguito:

documento esporta dati excel per appuntamento 5



Kutools for Outlook

Più di 100 Funzioni avanzate per Outlook 2010, 2013, 2016, 2019 e 365

screen shot kutools per outlook minuscolo per banner 201812

Altre caratteristiche | Scarica gratis | Solo $ 39.00 per centinaia di funzioni

Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.