Kaip automatiškai eksportuoti el. Laiškus iš "Outlook" į "Excel"?

Paprastai galite eksportuoti el. Laiškus iš "Outlook" į "Excel" naudodami funkciją "Import / Export". Bet ar kada nors bandėte automatiškai eksportuoti laiškus į "Excel" failą, kai atvyksta nauji pranešimai? Šiame straipsnyje aptarsiu, kaip automatiškai eksportuoti informaciją apie naujus gaunamus pranešimus "Excel".

Automatiškai eksportuoti el. Pašto informaciją iš perspektyvos į "Excel" su VBA kodu

Automatiškai eksportuoti el. Pašto informaciją iš perspektyvos į "Excel" su VBA kodu

Norėdami automatiškai eksportuoti naujus atvykstančius el. Laiškus į "Excel" darbaknygę, prašom pritaikyti šį VBA kodą:

1. Pirma, turėtumėte sukurti knygą su žemiau esančia antraštės informacija, kaip parodyta toliau pateiktoje ekrano kopijoje, taigi ši pranešimų informacija bus eksportuojama į šį "Excel" failą.

2. Tada eikite į "Outlook" ir laikykite nuspaudę ALT + F11 raktus atidaryti "Microsoft Visual Basic for Applications" langas.

3. Be "Microsoft Visual Basic for Applications" langas, dukart spustelėkite ThisOutlookSession nuo Project1 (VbaProject.OTM) kad atidarytumėte režimą, tada nukopijuokite ir įklijuokite šį kodą į tuščią modulį.

VBA kodas: automatiškai eksportuokite el. Pašto informaciją iš "Outlook" į "Excel" failą:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    Dim xMailItem As Outlook.MailItem
    Dim xExcelFile As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Excel.Workbook
    Dim xWs As Excel.Worksheet
    Dim xNextEmptyRow As Integer
    On Error Resume Next
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    xExcelFile = "C:\Users\DT168\Desktop\split document\kto-data.xlsx"
    If IsWorkBookOpen(xExcelFile) = True Then
        Set xExcelApp = GetObject(, "Excel.Application")
        Set xWb = GetObject(xExcelFile)
        If Not xWb Is Nothing Then xWb.Close True
    Else
        Set xExcelApp = New Excel.Application
    End If
    Set xWb = xExcelApp.Workbooks.Open(xExcelFile)
    Set xWs = xWb.Sheets(1)
    xNextEmptyRow = xWs.Range("B" & xWs.Rows.Count).End(xlUp).Row + 1
    With xWs
        .Cells(xNextEmptyRow, 1) = xNextEmptyRow - 1
        .Cells(xNextEmptyRow, 2) = xMailItem.SenderName
        .Cells(xNextEmptyRow, 3) = xMailItem.SenderEmailAddress
        .Cells(xNextEmptyRow, 4) = xMailItem.Subject
        .Cells(xNextEmptyRow, 5) = xMailItem.ReceivedTime
    End With
    xWs.Columns("A:E").AutoFit
    xWb.Save
End Sub
Function IsWorkBookOpen(FileName As String)
    Dim xFreeFile As Long, xErrNo As Long
    On Error Resume Next
    xFreeFile = FreeFile()
    Open FileName For Input Lock Read As #xFreeFile
    Close xFreeFile
    xErrNo = Err
    On Error GoTo 0
    Select Case xErrNo
        Case 0: IsWorkBookOpen = False
        Case 70: IsWorkBookOpen = True
        Case Else: Error xErrNo
    End Select
End Function

pastabos: Pirmiau nurodytu kodu C: \ Users \ DT168 \ Desktop \ split document \ kto-data.xlsx yra "Excel" failo kelias ir "Excel" pavadinimas, kuriuo norite rasti eksportuojamą informaciją, prašome jį pakeisti pagal savo poreikius.

4. Vis dar "Microsoft Visual Basic for Applications" langas, spustelėkite Įrankiai > Nuorodos eiti į Nuorodos-Project1 dialogo langas ir patikrinkite "Microsoft Excel" objektų biblioteka pasirinkimas iš Galimos nuorodos sąrašo langelis, žr. ekrano kopiją:

5. Tada spustelėkite OK mygtuką, kad uždarytumėte dialogą, tada išsaugokite ir uždarykite kodo langą.

6. Dabar norėdami, kad šis kodas pradėtų galioti, turėtumėte iš naujo paleisti "Outlook". Nuo šiol, atėjus naujiems el. Laiškams, jie bus eksportuojami į konkrečią darbo knygą automatiškai, žr. Ekrano kopiją:

Kutools for Outlook

Daugiau nei 100 papildomos funkcijos „Outlook 2010“, „2013“, „2016“, „2019“ ir „365“

Daugiau funkcijų | Nemokamas atsisiuntimas | Tik šimtai funkcijų - $ 39.00