Tips: Andre språk er Google-oversatt. Du kan besøke English versjon av denne lenken.
Logg inn
x
or
x
x
Registrere
x

or

Hvordan lager man avtale fra Excel-data?

Anta at du har en tabell med avtaledata i et Excel-regneark som følgende skjermbilde vist, nå vil du importere disse dataene til Outlook-kalenderen. Hvordan kunne du håndtere denne jobben raskt?

doc eksporter Excel-data til avtale 1

Opprett avtaler fra Excel-data med VBA-kode


Opprett avtaler fra Excel-data med VBA-kode

For å opprette avtaler fra Excel-data, kan du bruke følgende VBA-kode, gjør følgende:

1. Start Outlook og hold nede ALT + F11 nøkler for å åpne Microsoft Visual Basic for Applications vinduet.

2. Klikk innfelt > Modules, og lim inn følgende kode i Modules Vindu.

VBA-kode: Importer Excel-data til avtale:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Fortsatt i Microsoft Visual Basic for Applications vinduet klikker verktøy > Referanser å gå til Referanser-Project1 dialogboksen, og sjekk Microsoft Excel Object Library alternativ fra Tilgjengelige referanser listeboks, se skjermbilde:

doc eksporter Excel-data til avtale 2

4. Klikk deretter OK knappen, trykk nå F5 nøkkel for å kjøre denne koden, og a Velg en fil vinduet vises, velg Excel-filen du vil importere til Outlook, se skjermbilde:

doc eksporter Excel-data til avtale 3

5. Og klikk deretter OK, en ledig boks er poppet ut som følger:

doc eksporter Excel-data til avtale 4

6. Klikk deretter OK, har Excel-dataene blitt importert til kalenderen som følgende skjermbilde vist:

doc eksporter Excel-data til avtale 5



Kutools for Outlook

Mer enn 100 Avanserte funksjoner for Outlook 2010, 2013, 2016, 2019 og 365

skjermbildet kutools for Outlook liten for banner 201812

Flere funksjoner | Gratis nedlasting | Bare $ 39.00 for hundrevis av funksjoner

Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.
  • To post as a guest, your comment is unpublished.
    amiral · 1 days ago
    super cool il ya une erreur je la i rectifier mai apparament mes items colle pas mince



    olApp = Nothing ?
    xExcelApp.Quit