Совет. Другие языки - Google-Translated. Вы можете посетить English версия этой ссылки.
Войти
x
or
x
x
Регистрация
x

or

Excel IF функция

Функция IF - одна из самых простых и полезных функций в книге Excel. Он выполняет простой логический тест, который зависит от результата сравнения, и возвращает одно значение, если результат равен ИСТИНА, или другое значение, если результат равен ЛОЖЬ.


Синтаксис:

Синтаксис для функции IF в Excel:

=IF (logical_test, [value_if_true], [value_if_false])

док если функция 2


Аргументы:

  • logical_test: Необходимые. Это условие, которое вы хотите проверить.
  • value_if_true: Необязательный. Конкретное значение, которое вы хотите вернуть, если результат логического_теста равен TRUE.
  • value_if_false: Необязательный. Значение, которое вы хотите вернуть, если в качестве логического результата указано значение FALSE.

Примечания:

1. Если значение_если_истина опущено:

  • Если же линия индикатора значение_если_истина Аргумент пропущен в функции IF, такой как только запятая после логического_теста, он вернет ноль, когда условие выполнено. Например: =IF(C2>100,, "Low ").
  • Если вы хотите использовать пустую ячейку вместо нуля, если условие выполнено, вы должны ввести двойные кавычки "" во второй параметр, например так: =IF(C2>100, "", "Low").
док если функция 3 док если функция 4

2. Если значение_если_ложь опущено:

  • Если же линия индикатора значение_если_ложь Параметр пропущен в функции IF, он вернет FALSE, если указанное условие не выполнено. Такие как: =IF(C2>100, "High").
  • Если после аргумента value_if_true поставить запятую, она вернет ноль, если указанное условие не выполнено. Такие как: =IF(C2>100, "High" ,).
  • Если вы введете двойные кавычки "" в третий параметр, пустая ячейка вернется, если условие не выполнено. Такие как: =IF(C2>100, "High" , "").
док если функция 5 док если функция 6 док если функция 7

Вернуть:

Проверка определенного условия возвращает соответствующее значение, которое вы указали для ИСТИНА или ЛОЖЬ.


Примеры:

Пример 1: использование простой функции IF для чисел

Например, предположим, что вы хотите протестировать список значений, если значение больше определенного значения 100, отображается текст «Хорошо», если нет, возвращается текст «Плохо».

Введите приведенную ниже формулу, и вы получите следующий результат по мере необходимости.

=IF(B2>100,"Good","Bad")

док если функция 8


Пример 2: использование функции IF для текстовых значений

Case 1: IF-функция для текстовых значений с учетом регистра:

Здесь у меня есть таблица со списком задач и статусом завершения, теперь я хочу знать, какие задачи нужно выполнять, а какие нет. Когда текст в столбце C будет заполнен, отобразится «Нет», в противном случае будет возвращено «Да».

Пожалуйста, примените следующую формулу, теперь ячейка будет возвращать «Нет», когда текст в столбце С будет отображаться как «завершено», независимо от того, является ли он прописным или строчным; если другой текст в столбце C, будет возвращено «Да». Смотрите скриншот:

=IF(C2="completed", "No", "Yes")

док если функция 9

Case 2: функция IF для текстовых значений с учетом регистра:

Чтобы проверить значения текста с учетом регистра, вы должны объединить функцию IF с функцией EXACT, примените приведенную ниже формулу, тогда будет распознан только текст с точным соответствием, и вы получите желаемый результат ниже:

=IF(EXACT(C2,"COMPLETED"), "No", "Yes")

док если функция 10

Case 3: функция IF для текстовых значений с частичным совпадением:

Иногда вам нужно проверить значения ячеек на основе частичного текста, в этом случае вам следует использовать функции IF, ISNUMBER и SEARCH вместе.

Например, если вы хотите проверить ячейки, содержащие текст «comp», а затем вернуть соответствующие значения, примените приведенную ниже формулу. И вы получите результат, как показано на скриншоте ниже:

=IF(ISNUMBER(SEARCH("comp",C2)), "No", "Yes")

док если функция 11

Заметки:

  • 1. Функция ПОИСК применяется к тексту с учетом регистра, если вы хотите проверить текст с учетом регистра, вам следует заменить функцию ПОИСК на функцию НАЙТИ. Как это:=IF(ISNUMBER(FIND("comp",C2)), "No", "Yes")
  • 2. Текстовые значения в качестве параметров в формулах IF необходимо заключать в «двойные кавычки».

Пример 3: использование функции IF для значений даты

Case 1: функция IF для дат для сравнения дат с определенной датой:

Если вы хотите сравнить даты, чтобы проверить, являются ли они больше или меньше определенной даты, функция IF также может оказать вам услугу. Поскольку функция IF не может распознать формат даты, вам следует объединить с ним функцию DATEVALUE.

Пожалуйста, примените эту формулу, когда дата больше, чем 4 / 15 / 2019, будет возвращено «Да», в противном случае формула вернет текст «Нет», см. Скриншот:

=IF(D4>DATEVALUE("4/15/2019"), "Yes", "No")

док если функция 12

Внимание: В приведенной выше формуле вы можете напрямую использовать ссылку на ячейку, не используя функцию DATEVALUE. Как это: =IF(D4>$D$1, "Yes", "No").

док если функция 13

Случай 2: функция IF для дат для проверки дат больше или меньше дней 30:

Если вы хотите определить даты, которые больше или меньше дней 30 от текущей даты, вы можете объединить функцию TODAY с функцией IF.

Введите эту формулу:

Определите дату старше 30 дней: =IF(TODAY()-C4>30,"Older date","")

Определите дату, превышающую дни 30: =IF(C4-TODAY()>30, "Future date", "")

док если функция 14 док если функция 15

Примечание: Если вы хотите поместить оба результата в один столбец, вам нужно использовать вложенную функцию IF следующим образом:

=IF(C4-TODAY()>30, "Future date", IF(TODAY()-C4>30, "Older date", ""))

док если функция 16


Пример 4: Использование функции IF вместе с функцией AND, OR

Мы обычно используем для объединения функций IF, AND, OR в Excel.

Случай 1: Использование функции IF с функциями AND для проверки выполнения всех условий:

Я хочу проверить, все ли установленные мной условия выполняются, например: B4 - красный, C4 - маленький и D4> 200. Если все условия TURE, отметьте результат как «Да»; Если любое из условий ЛОЖЬ, верните «Нет».

Пожалуйста, примените эту формулу, и вы получите результат, как показано на следующем скриншоте:

=IF(AND(B4="Red",C4="Small", D4>200),"Yes","No")

док если функция 17

Случай 2: использование функции IF с функциями OR для проверки любого из условий выполняется:

Вы также можете использовать функции IF и OR, чтобы проверить, выполняется ли какое-либо из условий, например, я хочу определить, содержит ли ячейка в столбце B текст «Синий» или «Красный», если какой-либо текст в столбце B, Да отображается, в противном случае, нет возвращается.

Здесь вы должны применить эту формулу, и будет показан следующий результат:

=IF(OR(B4="Red",B4="Blue"),"Yes","No")

док если функция 18

Случай 3: Использование функции IF вместе с функциями AND и OR:

В этом примере я объединю функцию IF с функциями AND и OR одновременно. Предположим, вы должны проверить следующие условия:

  • Condition 1: Column B = “Red” and Column D > 300;
  • Condition 2: Column B = “Blue” and Column D > 300.

Если любое из вышеуказанных условий выполнено, возвращается Матч, в противном случае - Нет.

Пожалуйста, используйте эту формулу, и вы получите следующий результат по мере необходимости:

=IF(AND(OR(B4="Red",B4= "Blue"), D4>300), "Match", "No")

док если функция 19


Пример 5: использование функции Nested IF

Функция IF используется для проверки условия и возврата одного значения, если условие выполнено, и другого значения, если оно не выполнено. Но иногда вам нужно проверять более одного условия одновременно и возвращать разные значения, вы можете использовать Nested IF для решения этой задачи.

Вложенный оператор IF, который объединяет несколько условий IF, это означает помещение оператора IF в другой оператор IF и повторение этого процесса несколько раз.

Синтаксис для функции «Вложенный IF» в Excel:

=IF (condition1, result1, IF (condition2, result2, IF (condition3, result3,…)))

ВниманиеВ Excel 2007 и более поздних версиях вы можете вкладывать до 64 IF-функций в одну формулу, а в Excel 2003 и более ранних версиях можно использовать только вложенные функции 7 IF.

Case 1: вложенная функция IF для проверки нескольких условий:

Классическое использование функции «Вложенный IF» - это присвоение буквенного балла каждому ученику на основе его оценок. Например, у вас есть таблица со студентами и их экзаменационными баллами, теперь вы хотите классифицировать баллы по следующим условиям:

док если функция 20

Пожалуйста, примените эту формулу, и вы получите следующий результат, если оценка больше или равна 90, оценка «Отлично», если оценка больше или равна 80, оценка «Хорошо», если оценка больше или равно 60, оценка - «Средняя», в противном случае - «Плохая».

=IF(C2>=90, "Excellent", IF(C2>=80, "Good", IF(C2>=60, "Medium", "Poor")))

док если функция 21

Объяснение приведенной выше формулы:

док если функция 22
  • IF(check if C2>=90, if true - returns "Excellent", or else
  • IF(check if C2>=80, if true - returns "Good", or else
  • IF(check if C2>=60, if true - returns "Medium", if false - returns "Poor")))

Case 2: вложенная функция IF для расчета цены на основе количества:

Функция Nested IF также может быть использована для расчета цены продукта на основе количества.

Например, вы хотите предоставить покупателям ценовой разрыв на основе количества, большего количества, которое они покупают, большей скидки, которую они получат, как показано на скриншоте ниже.

док если функция 23

Поскольку общая цена равна количеству, умножьте цену, поэтому вы должны умножить указанное количество на значение, возвращаемое вложенными Ifs. Пожалуйста, используйте эту формулу:

=D2*IF(D2>=101,16, IF(D2>=50, 21, IF(D2>=25, 26, IF( D2>=11, 30, IF(D2>=1, 39, "")))))

док если функция 24

ВниманиеВы также можете использовать ссылки на ячейки для замены статических числовых чисел. Когда исходные данные меняются, вам не нужно обновлять формулу, используйте эту формулу: =D2*IF(D2>=101, B6, IF(D2>=50, B5, IF(D2>=25, B4, IF( D2>=11, B3, IF(D2>=1, B2, "")))))

док если функция 25

Советы: Используя функцию IF для построения теста, вы можете использовать следующие логические операторы:

оператор Смысл Пример Описание
> Больше =IF(A1>10, "OK",) Если число в ячейке A1 больше, чем 10, формула возвращает «ОК»; в противном случае возвращается 0.
< Менее =IF(A1<10, "OK", "") Если число в ячейке A1 меньше 10, формула возвращает «ОК»; в противном случае возвращается пустая ячейка.
> = Больше или равно =IF(A1>=10, "OK", "Bad") Если число в ячейке A1 больше или равно 10, возвращается «ОК»; в противном случае отображается «Плохо».
<= Меньше или равно =IF(A1<=10, "OK", "No") Если число в ячейке A1 меньше или равно 10, возвращается «ОК»; в противном случае возвращается «Нет».
= Равно =IF(A1=10, "OK", "No") Если число в ячейке A1 равно 10, возвращается «ОК»; в противном случае отображается «Нет».
<> Не равно =IF(A1<>10, "No", "OK") Если число в ячейке A1 не равно 10, формула возвращает «Нет»; в противном случае - «ОК».

Инструменты для повышения производительности Excel

Лента Excel (с установленным Kutools для Excel)

Расширенные функции 300 помогут вам выделиться из толпы

Хотели бы вы завершить свою ежедневную работу быстро и идеально? Kutools for Excel предоставляет мощные расширенные функции 300 (объединение рабочих книг, суммирование по цвету, разделение содержимого ячеек, конвертирование даты и т. д.) и экономию времени 80%.

  • Предназначен для рабочих сценариев 1500, помогает решать проблемы 80% Excel.
  • Ежедневно уменьшайте тысячи нажатий клавиш и клавиатуры, снимайте усталость с глаз и рук.
  • Станьте экспертом по Excel за минуты 3. Больше не нужно помнить какие-либо болезненные формулы и коды VBA.
  • 30-день неограниченная бесплатная пробная версия. 60-дневная гарантия возврата денег. Бесплатное обновление и поддержка 2 лет.

Снимок экрана Excel (с установленной вкладкой Office)

Приносит эффективные вкладки в офис (включая Excel), так же, как Chrome, Firefox и новый IE

  • Office Tab Повышает вашу производительность на 50% при просмотре и редактировании нескольких документов.
  • Сократите сотни щелчков мышью для вас каждый день, попрощайтесь с рукой мыши.
  • Одна секунда, чтобы переключаться между десятками открытых документов!
Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.