Si të eksportohet automatikisht email nga Outlook në Excel?

Normalisht, ju mund të eksportoni emailet nga Outlook në Excel me funksionin Import / Export. Por, a keni provuar ndonjëherë të eksportoheni automatikisht email-et në skedar Excel kur vijnë mesazhe të reja? Në këtë artikull, unë do të flas se si të eksportoj automatikisht informacionin e mesazheve të reja hyrëse në Excel.

Informacioni automatik i email-it të eksportit nga Outlook në Excel me kodin VBA

Informacioni automatik i email-it të eksportit nga Outlook në Excel me kodin VBA

Për të eksportuar automatikisht emailet e reja të ardhshme në një libër pune Excel, ju lutemi aplikoni kodin e mëposhtëm VBA:

1. Së pari, duhet të krijoni një libër pune me informacionin e mëposhtëm të mëposhtëm, si në vijim, kështu që këto informacione të mesazheve do të eksportohen në këtë skedar Excel.

2. Pastaj shkoni te Outlook dhe mbani shtypur ALT + F11 çelësat për të hapur Microsoft Visual Basic për Aplikime dritare.

3. në Microsoft Visual Basic për Aplikime dritare, klikoni dy herë ThisOutlookSession nga Project1 (VbaProject.OTM) panel për të hapur modalitetin, dhe pastaj kopjoni dhe ngjisni kodin e mëposhtëm në modulin bosh.

Kodi VBA: Informacion automatik i email-it të eksportit nga skedari Outlook në Excel:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    Dim xMailItem As Outlook.MailItem
    Dim xExcelFile As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Excel.Workbook
    Dim xWs As Excel.Worksheet
    Dim xNextEmptyRow As Integer
    On Error Resume Next
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    xExcelFile = "C:\Users\DT168\Desktop\split document\kto-data.xlsx"
    If IsWorkBookOpen(xExcelFile) = True Then
        Set xExcelApp = GetObject(, "Excel.Application")
        Set xWb = GetObject(xExcelFile)
        If Not xWb Is Nothing Then xWb.Close True
    Else
        Set xExcelApp = New Excel.Application
    End If
    Set xWb = xExcelApp.Workbooks.Open(xExcelFile)
    Set xWs = xWb.Sheets(1)
    xNextEmptyRow = xWs.Range("B" & xWs.Rows.Count).End(xlUp).Row + 1
    With xWs
        .Cells(xNextEmptyRow, 1) = xNextEmptyRow - 1
        .Cells(xNextEmptyRow, 2) = xMailItem.SenderName
        .Cells(xNextEmptyRow, 3) = xMailItem.SenderEmailAddress
        .Cells(xNextEmptyRow, 4) = xMailItem.Subject
        .Cells(xNextEmptyRow, 5) = xMailItem.ReceivedTime
    End With
    xWs.Columns("A:E").AutoFit
    xWb.Save
End Sub
Function IsWorkBookOpen(FileName As String)
    Dim xFreeFile As Long, xErrNo As Long
    On Error Resume Next
    xFreeFile = FreeFile()
    Open FileName For Input Lock Read As #xFreeFile
    Close xFreeFile
    xErrNo = Err
    On Error GoTo 0
    Select Case xErrNo
        Case 0: IsWorkBookOpen = False
        Case 70: IsWorkBookOpen = True
        Case Else: Error xErrNo
    End Select
End Function

shënim: Në kodin e mësipërm, C: \ Users \ DT168 \ Desktop \ nda dokumentin \ kto-data.xlsx është rruga e skedarit Excel dhe emri i Excel që dëshironi të gjeni informacionin e eksportuar, ju lutem ndryshoni atë në nevojën tuaj.

4. Ende në Microsoft Visual Basic për Aplikime dritare, klikoni Tools > Referencat për të shkuar në Referencat-Project1 kutinë e dialogut dhe kontrolloni Biblioteka e objekteve të Microsoft Excel opsion nga Referencat në dispozicion kutinë e listës, shihni screenshot:

5. Pastaj kliko OK button për të mbyllur dialogun dhe pastaj ruani dhe mbyllni dritaren e kodit.

6. Tani, duhet të rifilloni Outlook për ta bërë këtë kod të hyjë në fuqi. Nga tani e tutje, nëse ka email të ri që vijnë, ata do të eksportohen automatikisht në librin e punës të veçantë, shih screenshot:

Kutools për Outlook

Më shumë se 100 Funksione të Avancuara për Outlook 2010, 2013, 2016, 2019 dhe 365

më shumë Features | Shkarko falas | Vetëm $ 39.00 për qindra funksione