Cookie giúp chúng tôi cung cấp dịch vụ của chúng tôi. Bằng cách sử dụng dịch vụ của chúng tôi, bạn đồng ý sử dụng cookie.
Mẹo: Các ngôn ngữ khác được Dịch bởi Google. Bạn có thể ghé thăm English phiên bản của liên kết này.
Đăng nhập
x
or
x
x
Ghi danh
x

or

Cách tạo cuộc hẹn từ dữ liệu Excel?

Giả sử, bạn có một bảng dữ liệu cuộc hẹn trong một trang tính Excel như sau ảnh chụp màn hình được hiển thị, bây giờ, bạn muốn nhập dữ liệu này vào lịch Outlook. Làm thế nào bạn có thể đối phó với công việc này một cách nhanh chóng?

doc xuất dữ liệu excel sang cuộc hẹn 1

Tạo các cuộc hẹn từ dữ liệu Excel với mã VBA


Tạo các cuộc hẹn từ dữ liệu Excel với mã VBA

Để tạo các cuộc hẹn từ dữ liệu Excel, bạn có thể áp dụng mã VBA sau, hãy làm như sau:

1. Khởi chạy Outlook và giữ ALT + F11 phím để mở Microsoft Visual Basic cho các ứng dụng cửa sổ.

2. Nhấp chuột Chèn > Mô-đun, và dán mã sau trong Mô-đun Cửa sổ.

Mã VBA: Nhập dữ liệu excel vào cuộc hẹn:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Vẫn còn trong Microsoft Visual Basic cho các ứng dụng cửa sổ, nhấp Công cụ > dự án đi đến Tài liệu tham khảo-Project1 hộp thoại và kiểm tra Thư viện Đối tượng Microsoft Excel tùy chọn từ Tài liệu tham khảo có sẵn hộp danh sách, xem ảnh chụp màn hình:

doc xuất dữ liệu excel sang cuộc hẹn 2

4. Sau đó nhấn vào OK nút, bây giờ, nhấn F5 chìa khóa để chạy mã này, và Chọn một tập tin cửa sổ được hiển thị, vui lòng chọn tệp excel bạn muốn nhập vào Outlook, xem ảnh chụp màn hình:

doc xuất dữ liệu excel sang cuộc hẹn 3

5. Và sau đó nhấp vào OK, một hộp nhắc sẽ xuất hiện như sau:

doc xuất dữ liệu excel sang cuộc hẹn 4

6. Sau đó nhấn vào OK, dữ liệu Excel đã được nhập vào lịch như sau ảnh chụp màn hình hiển thị:

doc xuất dữ liệu excel sang cuộc hẹn 5



Kutools cho Outlook

Nhiều hơn các chức năng nâng cao 100 cho Outlook 2010, 2013, 2016, 2019 và 365

kutools chụp màn hình cho triển vọng nhỏ cho banner 201812

Các tính năng khác | Tải xuống miễn phí | Chỉ có $ 39.00 cho hàng trăm chức năng

Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.