How to reply normally in sent items folder from Outlook? 

Normally, when you click Reply feature in Sent items folder for sending another additional message for the people that you have sent, your own email address will be displayed at the To field as following screenshot shown. This may be annoying for you changing the address each time. How could make the Outlook use the original recipient's address, not yours?

Reply normally in Sent Items folder from Outlook with Reply All feature

Reply normally in Sent Items folder from Outlook with VBA code

Reply normally in Sent Items folder from Outlook with Reply All feature

In Outlook, the Reply All feature can help you to solve this problem, please do as this:

When you need to reply the sent email for sending again to keep the original recipient's address, please click Reply All button, and the original recipient's address is located at the To field as following screenshot shown:

Reply normally in Sent Items folder from Outlook with VBA code

Sometime, you may forget the Reply All feature when replying the sent message, so the below VBA code can help you reply normally in Sent Items folder by using the Reply feature. Do with following steps:

1. Hold down the ALT + F11 keys to open the Microsoft Visual Basic for Applications window.

2. In the Microsoft Visual Basic for Applications window, double click ThisOutlookSession from the Project1(VbaProject.OTM) pane to open the mode, and then copy and paste the following code into the blank module.

VBA code: Reply normally in Sent Items folder from Outlook:

Option Explicit
Private WithEvents GExplorer As Explorer
Private WithEvents GMailItem As MailItem
Private Sub Application_Startup()
    Set GExplorer = Application.ActiveExplorer
End Sub
Private Sub GExplorer_SelectionChange()
   On Error Resume Next
   Set GMailItem = GExplorer.Selection.Item(1)
End Sub
Private Sub GMailItem_Reply(ByVal Response As Object, Cancel As Boolean)
Dim xResponse As MailItem
Dim xRecipients As Outlook.Recipients
Dim xRecipient As Outlook.Recipient
Dim i As Integer
Dim xTo As String, xCC As String, xBCC As String, xName As String
On Error Resume Next
If Application.ActiveExplorer.CurrentFolder <> Session.GetDefaultFolder(olFolderSentMail) Then
    Exit Sub
End If
Cancel = True
Set xResponse = GMailItem.Reply
Set xRecipients = GMailItem.Recipients
For i = xRecipients.Count To 1 Step -1
    Set xRecipient = xRecipients.Item(i)
    xName = xRecipient.Name
    If Left(xName, 1) = "'" Then
        xName = Mid(xName, 2, Len(xRecipient.Name) - 2)
    End If
    Select Case xRecipient.Type
        Case olTo
            xTo = xName & ";" & xTo
        Case olCC
            xCC = xName & ";" & xCC
        Case olBCC
            xBCC = xName & ";" & xBCC
    End Select
Next
With xResponse
    .To = xTo
    .CC = xCC
    .BCC = xBCC
End With
xResponse.Recipients.ResolveAll
xResponse.Display
End Sub

3. Then, save the code, and restart the Outlook to take the code effect, now, when clicking Reply to resend an email in Sent Items folder, the original recipient's address is displayed at the To field as you need.