How to automatically save Outlook emails to hard drive/disk?

Author Kelly Last modified 2025-04-16

For backup, work evidences, or other purposes, you may want to save Outlook emails to hard drive. It’s easy to save several emails to disk with manually dragging from Outlook to disk. However, do you know how to automatically save each incoming email to disk? This article will introduce a VBA to handle it in Outlook.

Automatically save Outlook emails to hard drive/disk

Automatically save Outlook emails to hard drive/disk

This method will introduce a VBA to automatically save every incoming email in Outlook as individual HTML file to the specific disk. Please do as follows:

1. Press "Alt" + "F11" keys to open the Microsoft Visual Basic for Applications window.

2. Expand the Project1, and double click "ThisOutlookSession" to open it, and then paste below VBA code into the ThisOutlookSession window. See screenshot:

VBA: Automatically save Outlook emails as HTML files to disk

Private WithEvents InboxItems As Outlook.Items
Sub Application_Startup()
    Dim xNameSpace As Outlook.NameSpace
    Set xNameSpace = Outlook.Application.Session
    Set InboxItems = xNameSpace.GetDefaultFolder(olFolderInbox).Items
End Sub

Private Sub InboxItems_ItemAdd(ByVal objItem As Object)
    Dim FSO
    Dim xMailItem As Outlook.MailItem
    Dim xFilePath As String
    Dim xRegEx
    Dim xFileName As String
    On Error Resume Next
    xFilePath = CreateObject("WScript.Shell").SpecialFolders(16)
    xFilePath = xFilePath & "\MyEmails"
    Set FSO = CreateObject("Scripting.FileSystemObject")
    If FSO.FolderExists(xFilePath) = False Then
        FSO.CreateFolder (xFilePath)
    End If
    Set xRegEx = CreateObject("vbscript.regexp")
    xRegEx.Global = True
    xRegEx.IgnoreCase = False
    xRegEx.Pattern = "\||\/|\<|\>|""|:|\*|\\|\?"
    If objItem.Class = olMail Then
        Set xMailItem = objItem
        xFileName = xRegEx.Replace(xMailItem.Subject, "")
        xMailItem.SaveAs xFilePath & "\" & xFileName & ".html", olHTML
    End If
    Exit Sub
End Sub

3. Save the VBA code, and restart your Microsoft Outlook.

From now on, each incoming email will be saved as individual HTML file into the “MyEmails” folder.

Notes:
(1) This VBA will create a folder named “MyEmails” under the Documents folder. You can find out the automatically saved emails with this folder path: C:\Users\your_user_name\Documents\MyEmails
(2) This VBA will work with emails received in the Inbox folder of default email account.

How to export bulk/selected emails to Excel/Text/PST file in Outlook?