INDEX and MATCH across multiple columns

To lookup a value by matching across multiple columns, an array formula based on the INDEX and MATCH functions that incorporates MMULT, TRANSPOSE and COLUMN will do you a favor.

How to lookup a value by matching across multiple columns?

To fill in the corresponding class of each student as the above table shown, where the information is listed across multiple columns, you can first use the trick of the MMULT, TRANSPOSE and COLUMN function to produce a matrix array. Then the MATCH function will give you the position of your lookup value, which will be fed to INDEX to retrieve the value you are looking for in the array.

Generic syntax

=INDEX(return_range,(MATCH(1,MMULT(--(lookup_array=lookup_value),TRANSPOSE(COLUMN(lookup_array)^0)),0)))

√ Note: This is an array formula that requires you to enter with Ctrl + Shift + Enter.

To find the class of Jimmy, please copy or enter the formula below in the cell H5, and press Ctrl + Shift + Enter to get the result:

=INDEX($B$5:$B$7,(MATCH(1,MMULT(--($C$5:$E$7=G5),TRANSPOSE(COLUMN($C$5:$E$7)^0)),0)))

√ Note: The dollar signs ($) above indicate absolute references, which means the name and class ranges in the formula won't change when you move or copy the formula to other cells. Note that you should not add dollar signs to the cell reference that represents the lookup value, since you want it to be relative when you copy it to other cells. After you enter the formula, drag the fill handle down to apply the formula to the below cells.

Explanation of the formula

=INDEX($B$5:$B$7,(MATCH(1,MMULT(--($C$5:$E$7=G5),TRANSPOSE(COLUMN($C$5:$E$7)^0)),0)))

• --($C$5:$E$7=G5): This segment checks each value in the range $C$5:$E$7 if they equal to the value in the cell G5, and generates a TRUE and FALSE array like this:
  {TRUE,FALSE,FALSE;FALSE,FALSE,FALSE;FALSE,FALSE,FALSE}.
  The double negative will then convert the TRUEs and FALSEs to 1s and 0s to yield an array like this:
  {1,0,0;0,0,0;0,0,0}.
• COLUMN($C$5:$E$7): The COLUMN function returns the column numbers for the range $C$5:$E$7 in an array like this: {3,4,5}.
• TRANSPOSE(COLUMN($C$5:$E$7)^0) = TRANSPOSE({3,4,5}^0): After raising the power to 0, all the numbers in the array {3,4,5} will be converted to 1: {1,1,1}. The TRANSPOSE function then converts the column array to a row array like this: {1;1;1}.
• MMULT(--($C$5:$E$7=G5),TRANSPOSE(COLUMN($C$5:$E$7)^0)) = MMULT({1,0,0;0,0,0;0,0,0},{1;1;1}): The MMULT function returns the matrix product of the two arrays like this: {1;0;0}.
• MATCH(1,MMULT(--($C$5:$E$7=G5),TRANSPOSE(COLUMN($C$5:$E$7)^0)),0) = MATCH(1,{1;0;0},0): The match_type 0 forces the MATCH function to return the position of the first match of 1 in the array {1;0;0}, which is 1.
• INDEX($B$5:$B$7,(MATCH(1,MMULT(--($C$5:$E$7=G5),TRANSPOSE(COLUMN($C$5:$E$7)^0)),0))) = INDEX($B$5:$B$7,1): The INDEX function returns the 1st value in the class range $B$5:$B$7, which is A.

To easily lookup a value by matching across multiple columns, you can also use our professional Excel add-in Kutools For Excel. See the instruction here to accomplish the mission.

Related functions

Related Formulas