Astuce: Les autres langues sont Google-Traduction. Vous pouvez visiter le English version de ce lien.
Se connecter
x
or
x
x
S'enregistrer
x

or

Excel CHOOSE fonction

doc choisir la fonction 1

Description

Syntaxe et arguments

Usage et exemples


Description

Le CHOOSE fonction renvoie une valeur à partir de l'argument list of value basé sur le numéro d'index donné. Par exemple, CHOOSE(3,”Apple”,”Peach”,”Orange”) renvoie Orange, le numéro d'index est 3 et Orange est la troisième valeur après le numéro d'index dans la fonction.

syntaxe et arguments

Syntaxe de formule

CHOOSE(index_num, value1, [value2], …)

Arguments

  • Index_num: Champs obligatoires. Une valeur numérique comprise entre 1-254 et indirecte, valeur d'argument sélectionnée. si index_num est en dehors de l'échelle entre 1-254, CHOOSE renvoie le #VALUE! valeur d'erreur. Si index_num est une valeur décimale, elle sera arrondie à un nombre entier avant que la formule ne soit utilisée.
  • Value1: Champs obligatoires. La première valeur de la formule que vous pouvez choisir.
  • Value2: Optionnel. La seconde et jusqu’à la valeur 254th parmi laquelle choisir.

Value1, value2… Peuvent être des nombres, des textes, des formules, des références de cellules ou un nom défini.

Valeur de retour

Le CHOOSE La fonction retourne une valeur d'une liste basée sur la position donnée.

Usage et exemples

Dans cette partie, j’énumère quelques exemples simples mais représentatifs pour expliquer l’utilisation de CHOOSE la fonction.

Ex1 - Utilisation de base: utiliser CHOOSE fonction seule pour choisir la valeur de l'argument de liste

Formula1:

=CHOOSE(3,"a","b","c","d")

Retour: c, qui est le troisième argument après le index_num de 3 dans le CHOOSE la fonction.

Remarque: utilisez des guillemets doubles entourant la valeur s'il s'agit de texte.

Formula2:

=CHOOSE(2,A1,A2,A3,A4)

Retour: Kate, la valeur de A2. Comme index_num est 2 et A2 est la deuxième valeur de la CHOOSE la fonction.

Formula3:

=CHOOSE(4,8,9,7,6)

Retour: 6, l'argument de liste 4th dans la fonction.
doc choisir la fonction 2


Ex2 - Renvoie des résultats différents en fonction de plusieurs conditions

Supposons que vous disposiez d'une liste des écarts pour chaque produit devant être étiquetés en fonction des conditions décrites ci-dessous.
doc choisir la fonction 3

Habituellement, vous pouvez utiliser la fonction IF pour gérer, mais ici, je vous explique comment utiliser le CHOOSE fonction pour résoudre ce problème facilement

Formule:

=CHOOSE((B7>0)+(B7>1)+(B7>5),"Top","Middle","Bottom")

Explique:

(B7>0)+(B7>1)+(B7>5): L'index_num, B7 est 2, qui est plus grand que 0 et 1 mais inférieur à 5. Nous obtenons donc le résultat intermédiaire:

=CHOOSE(True+Ture+False,"Top","Middle","Bottom")

Comme nous le savons, True = 1, False = 0, de sorte que la formule peut être vue comme:

=CHOOSE(1+1+0,"Top","Middle","Bottom")

puis

=CHOOSE(2,"Top","Middle","Bottom")

Résultat: milieu
doc choisir la fonction 4


Ex3 - Renvoie différents résultats calculés en fonction de conditions

Supposons que vous deviez calculer les rabais pour chaque produit en fonction du montant et du prix, comme illustré ci-dessous:
doc choisir la fonction 5

Formule:

=CHOOSE((B8>0)+(B8>100)+(B8>200)+(B8>300),B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

Explique:

(B8>0)+(B8>100)+(B8>200)+(B8>300): index_number, B8 est 102, ce qui est supérieur à 100 mais inférieur à 201. Ainsi, dans cette partie, le résultat affiché est le suivant:

=CHOOSE(true+true+false+false,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

=CHOOSE(1+1+0+0,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

puis

=CHOOSE(2,B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5)

B8*C8*0.1,B8*C8*0.2,B8*C8*0.3,B8*C8*0.5: les valeurs parmi lesquelles choisir, remise correspond au prix * montant * pourcentage de remise, car ici index_num correspond à 2, il choisit B8 * C8 * 0.2

Renvoie: 102 * 2 * 0.2 = 40.8
doc choisir la fonction 6


Ex4 - Choisissez au hasard dans la liste

Dans Excel, vous devrez parfois choisir au hasard une valeur dans une liste donnée, la CHOOSE fonction peut résoudre ce travail.

Choisissez au hasard une valeur dans une liste:

Formule:

=CHOOSE(RANDBETWEEN(1,5),$D$2,$D$3,$D$4,$D$5,$D$6)

Explique:

RANDBETWEEN(1,5): index_num, obtenir un nombre aléatoire de 1 à 5

$D$2,$D$3,$D$4,$D$5,$D$6: la liste des valeurs à choisir
doc choisir la fonction 7


Ex5 - Combiner CHOOSE et VLOOKUP fonctions pour retourner la valeur dans la colonne de gauche

Généralement, nous utilisons la fonction VLOOKUP =VLOOKUP (value, table, col_index, [range_lookup]) pour renvoyer une valeur basée sur une valeur donnée d'une plage de table. Mais avec le VLOOKUP fonction, elle renverra une valeur d'erreur lorsque la colonne de retour se trouvera à gauche de la colonne de recherche, comme illustré ci-dessous:
doc choisir la fonction 8

Dans ce cas, vous pouvez combiner les CHOOSE fonction avec la fonction VLOOKUP pour résoudre le problème.

Formule:

=VLOOKUP(E1,CHOOSE({1,2},B1:B7,A1:A7),2,FALSE)

Explique:

CHOOSE({1,2},B1:B7,A1:A7): en tant qu'argument table_range dans la fonction VLOOKUP. {1,2} signifie afficher 1 ou 2 en tant qu'argument index_num en fonction de l'argument col_num de la fonction VLOOKUP. Ici, le nombre de colonnes dans la fonction VLOOKUP est 2, donc le CHOOSE affichage de la fonction comme CHOOSE(2, B1:B7,A1:A7), signifie choisir la valeur de A1: A7.
doc choisir la fonction 9


Ex6 - Retourne le jour de la semaine ou le mois en fonction de la date donnée

Avec le CHOOSE fonction, vous pouvez également renvoyer le jour de la semaine et le mois relatifs en fonction d’une date donnée.

Formule 1: retourne le jour de la semaine par une date

=CHOOSE(WEEKDAY(),"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday")

Explique:

WEEKDAY(): l'argument index_num, pour obtenir le numéro du jour de la semaine donné, par exemple, WEEKDAY (A5) renvoie 6, puis l'argument index_num est 6.

"Sunday","Monday","Tuesday","Wednesday","Thursday","Friday","Saturday": arguments de la liste de valeurs, commencez par «dimanche» car le numéro du jour de la semaine «1» indique «dimanche».

Formule 2: mois de retour par une date

=CHOOSE(MONTH(),"Jan","Feb","Mar","Apr","May","Jun","Jul","Aug","Sep","Oct","Nov","Dec")

Explique:

MONTH(): argument_index, qui obtient le numéro du mois à partir de la date donnée, par exemple, MONTH (A5) renvoie 3.
doc choisir la fonction 10


Ex7 - Retour à la date du jour ouvrable / week-end suivant

Dans le travail quotidien, vous pouvez calculer le jour ouvrable ou le week-end suivant en fonction de la journée. Ici le CHOOSE la fonction peut également vous faire une faveur.

Par exemple, aujourd'hui, nous sommes 12 / 20 / 2018, jeudi, vous devez maintenant obtenir le prochain jour ouvrable et le prochain week-end.

Formule 1: obtenir la date d'aujourd'hui

=TODAY()

Résultat: 12 / 20 / 2018

Formule 2: obtenir le numéro de semaine d'aujourd'hui

=WEEKDAY(TODAY())

Résultat: 5 (alors qu'aujourd'hui c'est 12 / 20 / 2018)

La liste des numéros de semaine comme ci-dessous la capture d'écran affichée:
doc choisir la fonction 10

Formule 3: obtenir le prochain jour ouvrable

=TODAY()+CHOOSE(WEEKDAY(TODAY()),1,1,1,1,1,3,2)

Explique:

Today(): renvoyer la date du jour

WEEKDAY(TODAY()): argument_index dans le CHOOSE fonction, obtenez le numéro du jour de la semaine d’aujourd’hui, par exemple, Sunday est 1, Monday est 2…

1,1,1,1,1,3,2: argument de liste de valeurs dans le CHOOSE une fonction. Par exemple, si jour de la semaine (today ()) renvoie 1 (dimanche), il choisit 1 dans la liste des valeurs, puis la formule entière devient = Today () + 1, ce qui signifie que 1 day doit être renvoyé lundi prochain. Si jour de la semaine (today ()) renvoie 6 (vendredi), il choisit 3 dans la liste de valeurs, car vendredi est le nombre de jours 3 qui se situe loin de lundi prochain.

Résultat (alors qu'aujourd'hui, c'est 12 / 20 / 2018):

=12/20/2018+CHOOSE(5,1,1,1,1,1,3,2)

= 12 / 20 / 2018 + 1

= 12 / 21 / 2018

Formule 4: obtenir le prochain week-end

=TODAY()+CHOOSE(WEEKDAY(TODAY()),6,5,4,3,2,1,1)

Explique:

6,5,4,3,2,1,1: argument de liste de valeurs dans le CHOOSE une fonction. Par exemple, si jour de la semaine (today ()) renvoie 1 (dimanche), il choisit 6 dans la liste des valeurs, puis la formule entière devient = Aujourd'hui () + 6, ce qui signifie d'ajouter des jours 6 et de revenir samedi prochain.

Résultat:

=12/20/2018+CHOOSE(5,6,5,4,3,2,1,1)

= 12 / 20 / 2018 + 2

= 12 / 22 / 2018
doc choisir la fonction 10


Exemple de fichier
exemple de fichier doc


Outils de productivité Excel

Ruban d'Excel (avec Kutools for Excel installé)

Les fonctionnalités avancées de 300 vous aident à vous démarquer de la foule

Voulez-vous terminer votre travail quotidien rapidement et parfaitement? Kutools for Excel apporte de puissantes fonctionnalités avancées 300 (combiner des classeurs, additionner par couleur, diviser le contenu des cellules, convertir une date, etc.) et économiser% de temps 80.

  • Conçu pour les scénarios de travail 1500, vous aide à résoudre les problèmes 80% Excel.
  • Réduisez chaque jour des milliers de clics au clavier et à la souris, soulagez vos yeux et vos mains fatigués.
  • Devenez un expert Excel en minutes 3. Plus besoin de se souvenir des formules douloureuses et des codes VBA.
  • Essai gratuit et illimité de 30-day. Garantie de remboursement 60-day. Mise à jour et support gratuits pour les années 2.

Capture d'écran d'Excel (avec l'onglet Office installé)

Apporte des onglets efficaces à Office (y compris Excel), à l'instar de Chrome, Firefox et du nouvel IE

  • Office Tab Augmente votre productivité de 50% lors de la visualisation et de la modification de plusieurs documents.
  • Réduisez chaque jour des centaines de clics de souris et dites au revoir à votre main.
  • Une seconde pour basculer entre des dizaines de documents ouverts!
Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.