Como exportar e-mails do Outlook para o Excel automaticamente?

Normalmente, você pode exportar os emails do Outlook para o Excel com o recurso Importar / Exportar. Mas, você já tentou exportar automaticamente os emails para o arquivo do Excel quando novas mensagens chegam? Neste artigo, vou falar sobre como exportar as informações das novas mensagens recebidas automaticamente no Excel.

Exportar automaticamente as informações de email do Outlook para o Excel com o código VBA

Exportar automaticamente as informações de email do Outlook para o Excel com o código VBA

Para exportar os novos emails que chegam para uma pasta de trabalho do Excel automaticamente, aplique o seguinte código VBA:

1. Primeiro, você deve criar uma pasta de trabalho com as informações de cabeçalho abaixo, como mostra a captura de tela a seguir, para que essas informações das mensagens sejam exportadas para esse arquivo do Excel.

2. Então vá para o Outlook e segure o ALT + F11 chaves para abrir o Microsoft Visual Basic para Aplicações janela.

3. No Microsoft Visual Basic para Aplicações janela, clique duas vezes ThisOutlookSession de Project1 (VbaProject.OTM) painel para abrir o modo e, em seguida, copie e cole o seguinte código no módulo em branco.

Código VBA: informações de e-mail de exportação automática do Outlook para o arquivo do Excel:

Public WithEvents GMailItems As Outlook.Items
Private Sub Application_Startup()
    Set GMailItems = Outlook.Application.Session.GetDefaultFolder(olFolderInbox).Items
End Sub
Private Sub GMailItems_ItemAdd(ByVal Item As Object)
    Dim xMailItem As Outlook.MailItem
    Dim xExcelFile As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Excel.Workbook
    Dim xWs As Excel.Worksheet
    Dim xNextEmptyRow As Integer
    On Error Resume Next
    If Item.Class <> olMail Then Exit Sub
    Set xMailItem = Item
    xExcelFile = "C:\Users\DT168\Desktop\split document\kto-data.xlsx"
    If IsWorkBookOpen(xExcelFile) = True Then
        Set xExcelApp = GetObject(, "Excel.Application")
        Set xWb = GetObject(xExcelFile)
        If Not xWb Is Nothing Then xWb.Close True
    Else
        Set xExcelApp = New Excel.Application
    End If
    Set xWb = xExcelApp.Workbooks.Open(xExcelFile)
    Set xWs = xWb.Sheets(1)
    xNextEmptyRow = xWs.Range("B" & xWs.Rows.Count).End(xlUp).Row + 1
    With xWs
        .Cells(xNextEmptyRow, 1) = xNextEmptyRow - 1
        .Cells(xNextEmptyRow, 2) = xMailItem.SenderName
        .Cells(xNextEmptyRow, 3) = xMailItem.SenderEmailAddress
        .Cells(xNextEmptyRow, 4) = xMailItem.Subject
        .Cells(xNextEmptyRow, 5) = xMailItem.ReceivedTime
    End With
    xWs.Columns("A:E").AutoFit
    xWb.Save
End Sub
Function IsWorkBookOpen(FileName As String)
    Dim xFreeFile As Long, xErrNo As Long
    On Error Resume Next
    xFreeFile = FreeFile()
    Open FileName For Input Lock Read As #xFreeFile
    Close xFreeFile
    xErrNo = Err
    On Error GoTo 0
    Select Case xErrNo
        Case 0: IsWorkBookOpen = False
        Case 70: IsWorkBookOpen = True
        Case Else: Error xErrNo
    End Select
End Function

notas: No código acima, C: \ Usuários \ DT168 \ Desktop \ documento dividido \ kto-data.xlsx é o caminho do arquivo do Excel eo nome do Excel que você deseja localizar as informações exportadas, altere-as conforme sua necessidade.

4. Ainda no Microsoft Visual Basic para Aplicações janela, clique em Ferramentas > caso para ir para o Referências-Project1 caixa de diálogo e verificação Biblioteca de Objetos do Microsoft Excel opção do Referências disponíveis caixa de listagem, veja a captura de tela:

5. Então clique OK botão para fechar a caixa de diálogo e, em seguida, salve e feche a janela de código.

6. Agora, você deve reiniciar o Outlook para que este código tenha efeito. De agora em diante, se houver novos e-mails chegando, eles serão exportados para a pasta de trabalho específica automaticamente, veja a captura de tela:

Kutools for Outlook

Mais do que 100 Funções avançadas para o Outlook 2010, 2013, 2016, 2019 e 365

mais recursos | Download grátis | Apenas $ 39.00 para centenas de funções