Tip: Iba pang mga wika ay isinaling-Google. Maaari mong bisitahin ang English bersyon ng link na ito.
mag-log in
x
or
x
x
Magrehistro
x

or

Paano gumawa ng appointment mula sa data ng Excel?

Kung kaya, mayroon kang isang talaan ng data ng appointment sa isang worksheet ng Excel tulad ng sumusunod na screenshot na ipinapakita, ngayon, gusto mong i-import ang mga data na ito sa kalendaryo ng Outlook. Paano mo mabilis na makikitungo sa trabaho na ito?

doc export excel data sa appointment 1

Lumikha ng mga appointment mula sa data ng Excel sa VBA code


Lumikha ng mga appointment mula sa data ng Excel sa VBA code

Upang lumikha ng mga appointment mula sa data ng Excel, maaari mong ilapat ang sumusunod na code ng VBA, mangyaring gawin ito:

1. Ilunsad ang Outlook at pindutin nang matagal ang ALT + F11 key upang buksan ang Microsoft Visual Basic para sa Mga Application window.

2. I-click ang Isingit > Module, at i-paste ang sumusunod na code sa Module Window.

VBA code: Mag-import ng excel data sa appointment:

Public Sub CreateOutlookApptz()
    Dim xAppointmentItem As Outlook.AppointmentItem
    Dim xNameSpace As Outlook.NameSpace
    Dim xCalendarFld As Outlook.MAPIFolder, xSubFolder As Outlook.MAPIFolder
    Dim xCalendarStr As String
    Dim I As Long
    Dim xFileDialog As FileDialog
    Dim xFilePath As String
    Dim xExcelApp As Excel.Application
    Dim xWb As Workbook
    Dim xWs As Worksheet
    On Error GoTo Err_Execute
    Set xExcelApp = New Excel.Application
    Set xFileDialog = xExcelApp.FileDialog(msoFileDialogFilePicker)
    With xFileDialog
        .Title = "Select a file"
        .Filters.Add "Microsoft Excel", "*.xlsx"
    End With
    If xFileDialog.Show = 0 Then Exit Sub
    xFilePath = xFileDialog.SelectedItems(1)
    Set xWb = xExcelApp.Workbooks.Open(xFilePath)
    Set xNameSpace = Outlook.Application.Session
    Set xCalendarFld = xNameSpace.GetDefaultFolder(olFolderCalendar)
    I = 2
    Set xWs = xWb.Worksheets.Item(1)
    xCalendarStr = xWb.Name
    If FolderExist(xCalendarFld, xCalendarStr) = False Then
        Set xSubFolder = xCalendarFld.Folders.Add(xCalendarStr, olFolderCalendar)
    Else
        Set xSubFolder = xCalendarFld.Folders(xCalendarStr)
    End If
    Do Until Trim(xWs.Cells(I, 1).Value) = ""
        Set xAppointmentItem = xSubFolder.Items.Add(olAppointmentItem)
        With xAppointmentItem
            .Start = xWs.Cells(I, 5) + xWs.Cells(I, 6)
            .End = xWs.Cells(I, 7) + xWs.Cells(I, 8)
            .Subject = xWs.Cells(I, 1)
            .Location = xWs.Cells(I, 2)
            .Body = xWs.Cells(I, 3)
            .BusyStatus = olBusy
            .ReminderMinutesBeforeStart = xWs.Cells(I, 9)
            .ReminderSet = True
            .Categories = xWs.Cells(I, 4)
            .Save
        End With
        I = I + 1
    Loop
    Set xAppointmentItem = Nothing
    Set olApp = Nothing
    xExcelApp.Quit
    Set xExcelApp = Nothing
    MsgBox "Import successfully!", vbInformation, "Kutools for Outlook"
    Exit Sub
Err_Execute:
    MsgBox "An error occurred - Exporting items to Calendar.", vbInformation, "Kutools for Outlook"
End Sub
Function FolderExist(CalFolder As Folder, FolderName As String) As Boolean
    Dim I As Integer
    Dim xSubFolder As Folder
    For I = 1 To CalFolder.Folders.Count
        Set xSubFolder = CalFolder.Folders.Item(I)
        If xSubFolder.Name = FolderName Then
            FolderExist = True
            Exit Function
        End If
    Next I
End Function

3. Pa rin sa Microsoft Visual Basic para sa Mga Application window, i-click ang Kagamitan > Mga sanggunian pumunta sa Mga sanggunian-Project1 dialog box, at suriin Microsoft Excel Object Library pagpipilian mula sa Magagamit na Mga Sanggunian kahon ng listahan, tingnan ang screenshot:

doc export excel data sa appointment 2

4. Pagkatapos ay mag-click OK pindutan, ngayon, pindutin F5 key upang patakbuhin ang code na ito, at a Pumili ng isang file Ipinapakita ang window, mangyaring piliin ang excel file na nais mong i-import sa Outlook, tingnan ang screenshot:

doc export excel data sa appointment 3

5. At pagkatapos ay mag-click OK, ang isang prompt na kahon ay binubunot bilang mga sumusunod:

doc export excel data sa appointment 4

6. Pagkatapos ay mag-click OK, ang data ng Excel ay na-import sa kalendaryo tulad ng sumusunod na screenshot na ipinapakita:

doc export excel data sa appointment 5



Kutools para sa Outlook

Higit sa 100 Advanced na Mga Function para sa Outlook 2010, 2013, 2016, 2019 at 365

screen shot kutools para sa pananaw maliit na maliit para sa banner 201812

Higit pang mga Tampok | Libreng pag-download | Tanging $ 39.00 para sa daan-daang mga pag-andar

Say something here...
symbols left.
You are guest ( Sign Up? )
or post as a guest, but your post won't be published automatically.
Loading comment... The comment will be refreshed after 00:00.

Be the first to comment.